mirror of
git://git.yoctoproject.org/linux-yocto.git
synced 2025-07-05 05:15:23 +02:00
62b672c4ba
Clear the backchain of the extra stack frame added by the vdso user wrapper
code. This allows the user stack walker to detect and skip the non-standard
stack frame. Without this an incorrect instruction pointer would be added
to stack traces, and stack frame walking would be continued with a more or
less random back chain.
Fixes: aa44433ac4 ("s390: add USER_STACKTRACE support")
Reviewed-by: Jens Remus <jremus@linux.ibm.com>
Signed-off-by: Heiko Carstens <hca@linux.ibm.com>
Signed-off-by: Alexander Gordeev <agordeev@linux.ibm.com>
59 lines
1.6 KiB
ArmAsm
59 lines
1.6 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
#include <linux/linkage.h>
|
|
#include <asm/vdso.h>
|
|
#include <asm/unistd.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/dwarf.h>
|
|
#include <asm/ptrace.h>
|
|
|
|
/*
|
|
* Older glibc version called vdso without allocating a stackframe. This wrapper
|
|
* is just used to allocate a stackframe. See
|
|
* https://sourceware.org/git/?p=glibc.git;a=commit;h=478593e6374f3818da39332260dc453cb19cfa1e
|
|
* for details.
|
|
*/
|
|
.macro vdso_func func
|
|
.globl __kernel_\func
|
|
.type __kernel_\func,@function
|
|
__ALIGN
|
|
__kernel_\func:
|
|
CFI_STARTPROC
|
|
aghi %r15,-STACK_FRAME_VDSO_OVERHEAD
|
|
CFI_DEF_CFA_OFFSET (STACK_FRAME_USER_OVERHEAD + STACK_FRAME_VDSO_OVERHEAD)
|
|
CFI_VAL_OFFSET 15,-STACK_FRAME_USER_OVERHEAD
|
|
stg %r14,__SFVDSO_RETURN_ADDRESS(%r15)
|
|
CFI_REL_OFFSET 14,__SFVDSO_RETURN_ADDRESS
|
|
xc __SFUSER_BACKCHAIN(8,%r15),__SFUSER_BACKCHAIN(%r15)
|
|
brasl %r14,__s390_vdso_\func
|
|
lg %r14,__SFVDSO_RETURN_ADDRESS(%r15)
|
|
CFI_RESTORE 14
|
|
aghi %r15,STACK_FRAME_VDSO_OVERHEAD
|
|
CFI_DEF_CFA_OFFSET STACK_FRAME_USER_OVERHEAD
|
|
CFI_RESTORE 15
|
|
br %r14
|
|
CFI_ENDPROC
|
|
.size __kernel_\func,.-__kernel_\func
|
|
.endm
|
|
|
|
vdso_func gettimeofday
|
|
vdso_func clock_getres
|
|
vdso_func clock_gettime
|
|
vdso_func getcpu
|
|
|
|
.macro vdso_syscall func,syscall
|
|
.globl __kernel_\func
|
|
.type __kernel_\func,@function
|
|
__ALIGN
|
|
__kernel_\func:
|
|
CFI_STARTPROC
|
|
svc \syscall
|
|
/* Make sure we notice when a syscall returns, which shouldn't happen */
|
|
.word 0
|
|
CFI_ENDPROC
|
|
.size __kernel_\func,.-__kernel_\func
|
|
.endm
|
|
|
|
vdso_syscall restart_syscall,__NR_restart_syscall
|
|
vdso_syscall sigreturn,__NR_sigreturn
|
|
vdso_syscall rt_sigreturn,__NR_rt_sigreturn
|