mirror of
git://git.yoctoproject.org/meta-dpdk.git
synced 2025-07-05 05:04:45 +02:00
f6895c0dd2
The SRC_URI should be "https://dpdk.org/git/dpdk" for https protocol. Otherwise it fails to fetch with git and fetch a tarball from premirror instead: WARNING: dpdk-module-22.07.0-r0 do_fetch: Failed to fetch URL git://dpdk.org/dpdk;branch=releases;protocol=https, attempting MIRRORS if available Signed-off-by: Kai Kang <kai.kang@windriver.com> Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
77 lines
1.8 KiB
BlitzBasic
77 lines
1.8 KiB
BlitzBasic
include dpdk.inc
|
|
|
|
SRC_URI = "git://dpdk.org/git/dpdk;branch=${BRANCH};protocol=https \
|
|
file://0001-meson.build-march-and-mcpu-already-passed-by-Yocto-21.11.patch \
|
|
"
|
|
|
|
BRANCH = "releases"
|
|
SRCREV = "4fceceed5b5e9fbf04acffd66239c79d81e79260"
|
|
S = "${WORKDIR}/git"
|
|
|
|
# CVE-2021-3839 has been fixed by commit 4c40d30d2b in 21.11.1
|
|
# NVD database is incomplete
|
|
# CVE-2022-0669 has been fixed by commit 6cb68162e4 in 21.11.1
|
|
# NVD database is incomplete
|
|
CVE_CHECK_IGNORE += "\
|
|
CVE-2021-3839 \
|
|
CVE-2022-0669 \
|
|
"
|
|
|
|
# kernel module is provide by dpdk-module recipe, so disable here
|
|
EXTRA_OEMESON = " -Denable_kmods=false \
|
|
-Dexamples=all \
|
|
"
|
|
|
|
COMPATIBLE_MACHINE = "null"
|
|
COMPATIBLE_HOST:libc-musl:class-target = "null"
|
|
COMPATIBLE_HOST:linux-gnux32 = "null"
|
|
|
|
PACKAGECONFIG ??= " "
|
|
PACKAGECONFIG[afxdp] = ",,libbpf xdp-tools"
|
|
PACKAGECONFIG[libvirt] = ",,libvirt"
|
|
|
|
RDEPENDS:${PN} += "pciutils python3-core"
|
|
RDEPENDS:${PN}-examples += "bash"
|
|
DEPENDS = "numactl python3-pyelftools-native"
|
|
|
|
inherit meson pkgconfig
|
|
|
|
INSTALL_PATH = "${prefix}/share/dpdk"
|
|
|
|
do_install:append(){
|
|
# remove source files
|
|
rm -rf ${D}/${INSTALL_PATH}/examples/*
|
|
|
|
# Install examples
|
|
install -m 0755 -d ${D}/${INSTALL_PATH}/examples/
|
|
for dirname in ${B}/examples/dpdk-*
|
|
do
|
|
if [ ! -d ${dirname} ] && [ -x ${dirname} ]; then
|
|
install -m 0755 ${dirname} ${D}/${INSTALL_PATH}/examples/
|
|
fi
|
|
done
|
|
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-examples ${PN}-tools"
|
|
|
|
FILES:${PN} += " ${bindir}/dpdk-testpmd \
|
|
${bindir}/dpdk-proc-info \
|
|
${libdir}/*.so* \
|
|
${libdir}/dpdk/pmds-22.0/*.so* \
|
|
"
|
|
FILES:${PN}-examples = " \
|
|
${prefix}/share/dpdk/examples/* \
|
|
"
|
|
|
|
FILES:${PN}-tools = " \
|
|
${bindir}/dpdk-pdump \
|
|
${bindir}/dpdk-test \
|
|
${bindir}/dpdk-test-* \
|
|
${bindir}/dpdk-*.py \
|
|
"
|
|
|
|
CVE_PRODUCT = "data_plane_development_kit"
|
|
|
|
INSANE_SKIP:${PN} = "dev-so"
|