u-boot-digi: Add Digi U-Boot for ConnectCore System-On-Modules

This vendor U-Boot is based on v2017.03 and currently supports two
ConnectCore 6UL memory variants, 256MB and 1GB.

To program this U-Boot from a running TFTP server
type the following at the U-Boot prompt:

env set ipaddr <target IP address>
env set serverip <TFTP server IP address>
update linux tftp <filename>

Where filename is:

* u-boot.imx-ccimx6ulstarter - for 256MB variants
* u-boot.imx-ccimx6ulstarter1GB - for 1GB variants

Signed-off-by: Alex Gonzalez <alex.gonzalez@digi.com>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

recipes-bsp/u-boot/u-boot-digi/ccimx6ul/bootscript.txt

@@ -0,0 +1,7 @@
+#
+# U-Boot bootscript for NAND images created by Yocto.
+#
+
+setenv fdt_file imx6ul-ccimx6ulsbcexpress.dtb
+setenv zimage zImage-ccimx6ulsbcexpress.bin
+dboot linux nand ${mtdbootpart}

recipes-bsp/u-boot/u-boot-digi_2017.03.bb

@@ -0,0 +1,40 @@
+# Copyright (C) 2018 Digi International
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "Bootloader for Digi platforms"
+SECTION = "bootloaders"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6"
+
+require recipes-bsp/u-boot/u-boot.inc
+
+DEPENDS = "u-boot-mkimage-native"
+
+PROVIDES += "u-boot"
+
+SRCBRANCH = "v2017.03/maint"
+SRCREV = "8d60f536d2063ac6a0676bdf34c4c8c8807371c5"
+
+SRC_URI = "\
+    git://github.com/digi-embedded/u-boot.git;protocol=git;nobranch=1 \
+    file://bootscript.txt \
+"
+
+LOCALVERSION ?= "-${SRCBRANCH}"
+
+S = "${WORKDIR}/git"
+
+inherit dtc-145 fsl-u-boot-localversion
+
+UBOOT_ENV = "boot"
+UBOOT_ENV_SUFFIX = "scr"
+
+do_compile_append () {
+    uboot-mkimage -A arm -O linux -T script -C none -a 0 -e 0 \
+        -n "boot script" -d ${WORKDIR}/bootscript.txt \
+        ${WORKDIR}/${UBOOT_ENV_BINARY}
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+COMPATIBLE_MACHINE = "(ccimx6ul)"