u-boot-boundary: add temporary v2017.03 version for imx8m

Hopefully i.MX8M support will soon be properly integrated into mainline
U-Boot so that we can use the same branch for all platforms.

Signed-off-by: Gary Bisson <gary.bisson@boundarydevices.com>

recipes-bsp/u-boot/u-boot-boundary-common_2017.03.imx8m.inc

@@ -0,0 +1,15 @@
+DESCRIPTION = "U-Boot for Boundary Devices boards"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6"
+
+PV = "v2017.03.imx8m+git${SRCPV}"
+
+SRCREV = "962210405277c99520aa4c5185c5aa2d589fbd1d"
+SRCBRANCH = "boundary-imx_v2017.03_4.9.51_imx8m_ga"
+SRC_URI = "git://github.com/boundarydevices/u-boot-imx6.git;branch=${SRCBRANCH}"
+
+DEPENDS += "dtc-native"
+
+S = "${WORKDIR}/git"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"

recipes-bsp/u-boot/u-boot-boundary_2017.03.imx8m.bb

@@ -0,0 +1,6 @@
+require recipes-bsp/u-boot/u-boot.inc
+require recipes-bsp/u-boot/u-boot-boundary-common_${PV}.inc
+
+PROVIDES += "u-boot"
+
+COMPATIBLE_MACHINE = "(nitrogen8m)"

recipes-bsp/u-boot/u-boot-script-boundary_2017.03.imx8m.bb

@@ -0,0 +1,45 @@
+require recipes-bsp/u-boot/u-boot-boundary-common_${PV}.inc
+
+DEPENDS = "u-boot-mkimage-native"
+
+inherit deploy
+
+BOOTSCRIPT ??= "${S}/board/boundary/bootscripts/bootscript-yocto.txt"
+BOOTSCRIPT_use-mainline-bsp ??= "${S}/board/boundary/bootscripts/bootscript-mainline.txt"
+
+UPGRADESCRIPT = "${S}/board/boundary/bootscripts/upgrade.txt"
+
+do_mkimage () {
+    uboot-mkimage -A arm64 -O linux -T script -C none -a 0 -e 0 \
+                  -n "boot script" -d ${BOOTSCRIPT} ${S}/boot.scr
+
+    uboot-mkimage -A arm64 -O linux -T script -C none -a 0 -e 0 \
+                  -n "upgrade script" -d ${UPGRADESCRIPT} ${S}/upgrade.scr
+}
+
+addtask mkimage after do_compile before do_install
+
+do_compile[noexec] = "1"
+
+do_install () {
+    install -D -m 644 ${S}/boot.scr ${D}/boot.scr
+    install -D -m 644 ${S}/upgrade.scr ${D}/upgrade.scr
+}
+
+do_deploy () {
+    install -D -m 644 ${D}/boot.scr \
+                      ${DEPLOYDIR}/boot.scr-${MACHINE}-${PV}-${PR}
+    install -D -m 644 ${D}/upgrade.scr \
+                      ${DEPLOYDIR}/upgrade.scr-${MACHINE}-${PV}-${PR}
+
+    cd ${DEPLOYDIR}
+    rm -f boot.scr-${MACHINE} upgrade.scr-${MACHINE}
+    ln -sf boot.scr-${MACHINE}-${PV}-${PR} boot.scr-${MACHINE}
+    ln -sf upgrade.scr-${MACHINE}-${PV}-${PR} upgrade.scr-${MACHINE}
+}
+
+addtask deploy after do_install before do_build
+
+FILES_${PN} += "/"
+
+COMPATIBLE_MACHINE = "(nitrogen8m)"