mirror of
https://github.com/Freescale/meta-freescale-3rdparty.git
synced 2025-07-19 12:09:01 +02:00
983da16f73
Hopefully i.MX8M support will soon be properly integrated into mainline U-Boot so that we can use the same branch for all platforms. Signed-off-by: Gary Bisson <gary.bisson@boundarydevices.com>
46 lines
1.3 KiB
BlitzBasic
46 lines
1.3 KiB
BlitzBasic
require recipes-bsp/u-boot/u-boot-boundary-common_${PV}.inc
|
|
|
|
DEPENDS = "u-boot-mkimage-native"
|
|
|
|
inherit deploy
|
|
|
|
BOOTSCRIPT ??= "${S}/board/boundary/bootscripts/bootscript-yocto.txt"
|
|
BOOTSCRIPT_use-mainline-bsp ??= "${S}/board/boundary/bootscripts/bootscript-mainline.txt"
|
|
|
|
UPGRADESCRIPT = "${S}/board/boundary/bootscripts/upgrade.txt"
|
|
|
|
do_mkimage () {
|
|
uboot-mkimage -A arm64 -O linux -T script -C none -a 0 -e 0 \
|
|
-n "boot script" -d ${BOOTSCRIPT} ${S}/boot.scr
|
|
|
|
uboot-mkimage -A arm64 -O linux -T script -C none -a 0 -e 0 \
|
|
-n "upgrade script" -d ${UPGRADESCRIPT} ${S}/upgrade.scr
|
|
}
|
|
|
|
addtask mkimage after do_compile before do_install
|
|
|
|
do_compile[noexec] = "1"
|
|
|
|
do_install () {
|
|
install -D -m 644 ${S}/boot.scr ${D}/boot.scr
|
|
install -D -m 644 ${S}/upgrade.scr ${D}/upgrade.scr
|
|
}
|
|
|
|
do_deploy () {
|
|
install -D -m 644 ${D}/boot.scr \
|
|
${DEPLOYDIR}/boot.scr-${MACHINE}-${PV}-${PR}
|
|
install -D -m 644 ${D}/upgrade.scr \
|
|
${DEPLOYDIR}/upgrade.scr-${MACHINE}-${PV}-${PR}
|
|
|
|
cd ${DEPLOYDIR}
|
|
rm -f boot.scr-${MACHINE} upgrade.scr-${MACHINE}
|
|
ln -sf boot.scr-${MACHINE}-${PV}-${PR} boot.scr-${MACHINE}
|
|
ln -sf upgrade.scr-${MACHINE}-${PV}-${PR} upgrade.scr-${MACHINE}
|
|
}
|
|
|
|
addtask deploy after do_install before do_build
|
|
|
|
FILES_${PN} += "/"
|
|
|
|
COMPATIBLE_MACHINE = "(nitrogen8m)"
|