mirror of
https://github.com/Freescale/meta-freescale-3rdparty.git
synced 2025-07-19 20:19:01 +02:00
cfa072dec7
The main goal of this update is to address the issues reported by Otavio using 6x_bootscript-mainline.txt with mainline Linux [1]. Here is a full log of the bump: 568947b9d1 6x_bootscript-mainline: introduce rfspart variable 8c7e53d06f 6x_bootscript-mainline: use UUID to identify root partition eb4c55af25 6x_bootscript-mainline: fixup LVDS2 display handling 6e4b9009e7 ahci: extend data io wait to 20s 4e4c6006f7 boundary.h: add CONFIG_CMD_PART bc55c1e287 6x_bootscript-mainline: change default bootdir to be / d1c5c4bf98 nitrogen6_max: add ND-070PCAP-1024x600 e7b6e555c4 fbpanel: add ND-070PCAP-1024x600 cf2b52b5d9 mtp: update 2G quadplus calibration based on 15 boards b8b3e1958b mtp: gadget mac is in ethaddr not eth1addr, because no FEC 143d864e2b ahci: extend data io wait to 15s 7ef83873fe 6x_upgrade: re-introduce fs-specific load commands 9dcb694789 lshore: add pin definitions for rev1.1 fd3d0f65c6 ddr-setup.cfg: increase WALAT to 1 cycle [1] https://lists.yoctoproject.org/pipermail/meta-freescale/2017-March/020299.html Signed-off-by: Gary Bisson <gary.bisson@boundarydevices.com> Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
63 lines
2.0 KiB
BlitzBasic
63 lines
2.0 KiB
BlitzBasic
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6"
|
|
DEPENDS = "u-boot-mkimage-native"
|
|
|
|
PV = "v2016.03+git${SRCPV}"
|
|
|
|
SRCREV = "568947b9d1dd4e966008fceb4617392a82dc753c"
|
|
SRCBRANCH = "boundary-v2016.03"
|
|
SRC_URI = "git://github.com/boundarydevices/u-boot-imx6.git;branch=${SRCBRANCH}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit deploy
|
|
|
|
BOOTSCRIPT ?= "${S}/board/boundary/nitrogen6x/6x_bootscript-yocto-3.14.txt"
|
|
|
|
UPGRADESCRIPT = "${S}/board/boundary/nitrogen6x/6x_upgrade.txt"
|
|
|
|
do_mkimage () {
|
|
# allow deploy to use the ${MACHINE} name to simplify things
|
|
if [ ! -d ${S}/board/boundary/${MACHINE} ]; then
|
|
mkdir ${S}/board/boundary/${MACHINE}
|
|
fi
|
|
|
|
uboot-mkimage -A arm -O linux -T script -C none -a 0 -e 0 \
|
|
-n "boot script" -d ${BOOTSCRIPT} \
|
|
${S}/board/boundary/${MACHINE}/6x_bootscript
|
|
|
|
uboot-mkimage -A arm -O linux -T script -C none -a 0 -e 0 \
|
|
-n "upgrade script" -d ${UPGRADESCRIPT} \
|
|
${S}/board/boundary/${MACHINE}/6x_upgrade
|
|
}
|
|
|
|
addtask mkimage after do_compile before do_install
|
|
|
|
do_compile[noexec] = "1"
|
|
|
|
do_install () {
|
|
install -D -m 644 ${S}/board/boundary/${MACHINE}/6x_bootscript \
|
|
${D}/6x_bootscript
|
|
install -D -m 644 ${S}/board/boundary/${MACHINE}/6x_upgrade \
|
|
${D}/6x_upgrade
|
|
}
|
|
|
|
do_deploy () {
|
|
install -D -m 644 ${D}/6x_bootscript \
|
|
${DEPLOYDIR}/6x_bootscript-${MACHINE}-${PV}-${PR}
|
|
install -D -m 644 ${D}/6x_upgrade \
|
|
${DEPLOYDIR}/6x_upgrade-${MACHINE}-${PV}-${PR}
|
|
|
|
cd ${DEPLOYDIR}
|
|
rm -f 6x_bootscript-${MACHINE} 6x_upgrade-${MACHINE}
|
|
ln -sf 6x_bootscript-${MACHINE}-${PV}-${PR} 6x_bootscript-${MACHINE}
|
|
ln -sf 6x_upgrade-${MACHINE}-${PV}-${PR} 6x_upgrade-${MACHINE}
|
|
}
|
|
|
|
addtask deploy after do_install before do_build
|
|
|
|
FILES_${PN} += "/"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
COMPATIBLE_MACHINE = "(nitrogen6x|nitrogen6x-lite|nitrogen6sx|nitrogen7)"
|