imx-gpu-sdk: Add new packages

Add recipes for imx-gpu-sdk dependencies:
- gli
- half
- stb
- rapidopencl
- rapidopenvx
- rapidvulkan

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>
(cherry picked from commit 305b9ded6e)

recipes-devtools/half/half_2.1.0.bb

@@ -0,0 +1,20 @@
+SUMMARY = "C++ library for half precision floating point arithmetics"
+DESCRIPTION = "half is a C++ header-only library to provide an IEEE-754 conformant \ 
+half-precision floating point type along with corresponding arithmetic operators, \
+type conversions and common mathematical functions."
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=813a6278831975d26c115ed6f9c21831"
+
+SRC_URI = "https://sourceforge.net/projects/half/files/half/${PV}/${BP}.zip"
+SRC_URI[md5sum] = "cd28e42c77b99e4cca4f5e9fc76e0433"
+SRC_URI[sha256sum] = "ad1788afe0300fa2b02b0d1df128d857f021f92ccf7c8bddd07812685fa07a25"
+
+S = "${WORKDIR}"
+
+do_install () {
+    install -d ${D}${includedir}
+    cp -r ${S}/include/* ${D}${includedir}
+}
+
+ALLOW_EMPTY_${PN} = "1"

recipes-devtools/stb/stb_git.bb

@@ -0,0 +1,17 @@
+SUMMARY = "single-file public domain (or MIT licensed) libraries for C/C++"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://stb.h;beginline=14418;endline=14433;md5=b10975d4c8155af1811ab611586f01d2"
+
+PV = "0.0+git${SRCPV}"
+
+SRCREV = "f67165c2bb2af3060ecae7d20d6f731173485ad0"
+SRC_URI = "git://github.com/nothings/stb.git"
+
+S = "${WORKDIR}/git"
+
+do_install() {
+    install -d ${D}${includedir}
+    for hdr in ${S}/*.h; do
+        install -m 0644 $hdr ${D}${includedir}
+    done
+}

recipes-graphics/gli/gli/0001-Set-C-standard-through-CMake-standard-options.patch

@@ -0,0 +1,33 @@
+From a2d4a3a912a001bc5483e0d8fd178af422814394 Mon Sep 17 00:00:00 2001
+From: Ian Hattendorf <ian@ianhattendorf.com>
+Date: Mon, 19 Mar 2018 13:57:10 -0700
+Subject: [PATCH] Set C++ standard through CMake standard options
+
+Upstream-Status: Backport [https://github.com/g-truc/gli/commit/a2d4a3a912a001bc5483e0d8fd178af422814394]
+
+---
+ CMakeLists.txt | 4 +++-
+ 1 file changed, 3 insertions(+), 1 deletion(-)
+
+Index: git/CMakeLists.txt
+===================================================================
+--- git.orig/CMakeLists.txt
++++ git/CMakeLists.txt
+@@ -6,6 +6,9 @@ endif()
+ 
+ project(gli)
+ set(GLI_VERSION "0.8.1")
++set(CMAKE_CXX_STANDARD 11)
++set(CMAKE_CXX_STANDARD_REQUIRED ON)
++set(CMAKE_CXX_EXTENSIONS OFF)
+ 
+ list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
+ 
+@@ -24,7 +27,6 @@ if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "
+ endif()
+ 
+ if(("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang") OR ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU") OR (("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel") AND UNIX))
+-	set(CMAKE_CXX_FLAGS "-std=c++0x")
+ 	add_definitions(-Wall)
+ endif()
+ 

recipes-graphics/gli/gli_0.8.2.0.bb

@@ -0,0 +1,24 @@
+SUMMARY = "OpenGL Image Library"
+DESCRIPTION = "OpenGL Image (GLI) is a header only C++ \
+image library for graphics software."
+HOMEPAGE = "http://gli.g-truc.net"
+BUGTRACKER = "https://github.com/g-truc/gli/issues"
+
+SECTION = "libs"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://readme.md;beginline=19;endline=20;md5=ab03b667ee630c1abb1add70365a50fb"
+
+SRC_URI = " \
+    git://github.com/g-truc/gli;branch=0.8.2 \
+    file://0001-Set-C-standard-through-CMake-standard-options.patch \
+"
+SRCREV = "30808550a20ca53a255e6e1e77070493eda7b736"
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+FILES_${PN}-dev += "${libdir}/cmake"
+RDEPENDS_${PN}-dev = ""
+
+BBCLASSEXTEND = "native"

recipes-graphics/rapidopencl/rapidopencl_1.1.0.1.bb

@@ -0,0 +1,18 @@
+SUMMARY = "Experimental low level header only C++11 RAII wrapper classes for the OpenCL API"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b98f636daed34d12d11e25f3185c0204"
+
+SRC_URI = "git://github.com/Unarmed1000/RapidOpenCL;protocol=https \
+"
+SRCREV = "21254804a56ae96e8385c2652733c338d62da04f"
+
+S = "${WORKDIR}/git"
+
+# RapidOpenCL is a header-only C++11 RAII wrapper class, so the main package will be empty.
+
+do_install () {
+    install -d ${D}${includedir}
+    cp -r ${S}/include/* ${D}${includedir}
+}
+
+ALLOW_EMPTY_${PN} = "1"

recipes-graphics/rapidopenvx/rapidopenvx_1.1.0.bb

@@ -0,0 +1,16 @@
+SUMMARY = "Low level header only C++11 RAII wrapper classes for the OpenVX API"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b98f636daed34d12d11e25f3185c0204"
+
+SRC_URI = "git://github.com/Unarmed1000/RapidOpenVX;protocol=https \
+"
+SRCREV = "909c7abbff0ee35610f07f6fadeaf3a2eadce36e"
+
+S = "${WORKDIR}/git"
+
+do_install () {
+    install -d ${D}${includedir}
+    cp -r ${S}/include/* ${D}${includedir}
+}
+
+ALLOW_EMPTY_${PN} = "1"

recipes-graphics/rapidvulkan/rapidvulkan_1.2.131.1.bb

@@ -0,0 +1,14 @@
+SUMMARY = "Low level header only C++11 RAII wrapper classes for the Vulkan API"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=b98f636daed34d12d11e25f3185c0204"
+
+DEPENDS = "vulkan-loader"
+
+SRC_URI = "git://github.com/Unarmed1000/RapidVulkan;protocol=https"
+SRCREV = "19324a3300771a0c30090111975f348a3ec92dab"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+ALLOW_EMPTY_${PN} = "1"