mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-07-05 05:14:44 +02:00
b747b01501
The series [1] changed the way sources are fetched/unpacked and S needs to follow that. Additionally for git repos it moved away from having 'git/' as the checkout directory. This has been partly tested by building weston based image for imx6/imx6ull/imx7/imx8/imx8mm/imx8mp/imx95 based images. E.g. none of the recipes specific for qoriq is built time tested. As walnascar is no longer compatible with master/whinlatter drop it from LAYERSERIES_COMPAT. [1] https://lore.kernel.org/openembedded-core/20250616095000.2918921-1-alex.kanavin@gmail.com/ Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
60 lines
1.3 KiB
BlitzBasic
60 lines
1.3 KiB
BlitzBasic
SUMMARY = "i.MX Optional Execution Image"
|
|
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=59530bdf33659b29e73d4adb9f9f6552"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS = "gcc-arm-none-eabi-native"
|
|
|
|
SRC_URI = "${IMX_OEI_SRC};branch=${SRCBRANCH}"
|
|
IMX_OEI_SRC ?= "git://github.com/nxp-imx/imx-oei.git;protocol=https"
|
|
SRCBRANCH = "master"
|
|
SRCREV = "1a572a640ef8d6883e8ca39744cd6d2d5dbed678"
|
|
|
|
inherit deploy
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
OEI_CONFIGS ?= "UNDEFINED"
|
|
OEI_CORE ?= "UNDEFINED"
|
|
OEI_SOC ?= "UNDEFINED"
|
|
OEI_BOARD ?= "UNDEFINED"
|
|
|
|
LDFLAGS[unexport] = "1"
|
|
|
|
EXTRA_OEMAKE = "\
|
|
board=${OEI_BOARD} \
|
|
DEBUG=1 \
|
|
OEI_CROSS_COMPILE=arm-none-eabi-"
|
|
|
|
do_configure() {
|
|
for oei_config in ${OEI_CONFIGS}; do
|
|
oe_runmake clean oei=$oei_config
|
|
done
|
|
}
|
|
|
|
do_compile() {
|
|
for oei_config in ${OEI_CONFIGS}; do
|
|
oe_runmake oei=$oei_config
|
|
done
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/firmware
|
|
for oei_config in ${OEI_CONFIGS}; do
|
|
install -m 0644 ${B}/build/${OEI_BOARD}/$oei_config/oei-*.bin ${D}/firmware
|
|
done
|
|
}
|
|
|
|
addtask deploy after do_install
|
|
do_deploy() {
|
|
cp -rf ${D}/firmware/* ${DEPLOYDIR}/
|
|
}
|
|
|
|
FILES:${PN} = "/firmware"
|
|
SYSROOT_DIRS += "/firmware"
|
|
|
|
PROVIDES += "virtual/imx-oei"
|
|
|
|
COMPATIBLE_MACHINE = "(mx95-generic-bsp)"
|