mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-07-19 12:59:04 +02:00
b747b01501
The series [1] changed the way sources are fetched/unpacked and S needs to follow that. Additionally for git repos it moved away from having 'git/' as the checkout directory. This has been partly tested by building weston based image for imx6/imx6ull/imx7/imx8/imx8mm/imx8mp/imx95 based images. E.g. none of the recipes specific for qoriq is built time tested. As walnascar is no longer compatible with master/whinlatter drop it from LAYERSERIES_COMPAT. [1] https://lore.kernel.org/openembedded-core/20250616095000.2918921-1-alex.kanavin@gmail.com/ Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
86 lines
2.8 KiB
BlitzBasic
86 lines
2.8 KiB
BlitzBasic
# Copyright (C) 2012-2016 O.S. Systems Software LTDA.
|
|
# Copyright (C) 2013-2016 Freescale Semiconductor
|
|
# Copyright (C) 2017-2022 NXP
|
|
|
|
SUMMARY = "Test programs for i.MX BSP"
|
|
DESCRIPTION = "Unit tests for the i.MX BSP"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0-or-later;md5=fed54355545ffd980b814dab4a3b312c"
|
|
|
|
DEPENDS = "alsa-lib freetype libdrm"
|
|
DEPENDS:append:imxvpu = " virtual/imxvpu"
|
|
DEPENDS:append:mx6-nxp-bsp = " imx-lib"
|
|
DEPENDS:append:mx7-nxp-bsp = " imx-lib"
|
|
DEPENDS:append:mx8ulp-nxp-bsp = " imx-lib"
|
|
DEPENDS:append:mx93-nxp-bsp = " imx-lib"
|
|
|
|
PE = "1"
|
|
PV = "7.0+${SRCPV}"
|
|
|
|
SRC_URI = "git://github.com/nxp-imx/imx-test.git;protocol=https;branch=${SRCBRANCH} \
|
|
file://memtool_profile"
|
|
SRCBRANCH = "lf-6.12.3_1.0.0"
|
|
SRCREV = "92a497313016bfa536d561e13fcbad2d273ded4c"
|
|
|
|
inherit module-base use-imx-headers
|
|
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
|
|
|
|
PLATFORM:mx6q-nxp-bsp = "IMX6Q"
|
|
PLATFORM:mx6dl-nxp-bsp = "IMX6Q"
|
|
PLATFORM:mx6sl-nxp-bsp = "IMX6SL"
|
|
PLATFORM:mx6sll-nxp-bsp = "IMX6SL"
|
|
PLATFORM:mx6sx-nxp-bsp = "IMX6SX"
|
|
PLATFORM:mx6ul-nxp-bsp = "IMX6UL"
|
|
PLATFORM:mx7d-nxp-bsp = "IMX7D"
|
|
PLATFORM:mx7ulp-nxp-bsp = "IMX7D"
|
|
PLATFORM:mx8-nxp-bsp = "IMX8"
|
|
PLATFORM:mx8ulp-nxp-bsp = "IMX8ULP"
|
|
PLATFORM:mx91-nxp-bsp = "IMX8"
|
|
PLATFORM:mx93-nxp-bsp = "IMX8ULP"
|
|
PLATFORM:mx95-nxp-bsp = "IMX8"
|
|
|
|
PARALLEL_MAKE = "-j 1"
|
|
EXTRA_OEMAKE += "${PACKAGECONFIG_CONFARGS}"
|
|
|
|
PACKAGECONFIG = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
|
|
PACKAGECONFIG:append:imxvpu = " vpu"
|
|
PACKAGECONFIG:append:mx8m-nxp-bsp = " swpdm"
|
|
|
|
PACKAGECONFIG[x11] = ",,libx11 libxdamage libxrender libxrandr"
|
|
PACKAGECONFIG[vpu] = "HAS_VPU=true,HAS_VPU=false,virtual/imxvpu"
|
|
PACKAGECONFIG[swpdm] = "HAS_IMX_SW_PDM=true,HAS_IMX_SW_PDM=false,imx-sw-pdm"
|
|
|
|
do_compile() {
|
|
CFLAGS="${TOOLCHAIN_OPTIONS}"
|
|
oe_runmake V=1 VERBOSE='' \
|
|
CROSS_COMPILE=${TARGET_PREFIX} \
|
|
INC="-I${S}/include \
|
|
-I${STAGING_INCDIR} \
|
|
-I${STAGING_INCDIR_IMX}" \
|
|
CC="${CC} -L${STAGING_LIBDIR} ${LDFLAGS}" \
|
|
SDKTARGETSYSROOT=${STAGING_DIR_HOST} \
|
|
LINUXPATH=${STAGING_KERNEL_DIR} \
|
|
KBUILD_OUTPUT=${STAGING_KERNEL_BUILDDIR} \
|
|
PLATFORM=${PLATFORM}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D}/unit_tests \
|
|
PLATFORM=${PLATFORM} \
|
|
install
|
|
|
|
if [ -e ${UNPACKDIR}/clocks.sh ]; then
|
|
install -m 755 ${UNPACKDIR}/clocks.sh ${D}/unit_tests/clocks.sh
|
|
fi
|
|
install -d -m 0755 ${D}${ROOT_HOME}/
|
|
install -m 0644 ${UNPACKDIR}/memtool_profile ${D}${ROOT_HOME}/.profile
|
|
}
|
|
|
|
FILES:${PN} += "/unit_tests ${ROOT_HOME}/.profile"
|
|
RDEPENDS:${PN} = "bash"
|
|
|
|
FILES:${PN}-dbg += "/unit_tests/.debug"
|