mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-07-19 12:59:04 +02:00
b747b01501
The series [1] changed the way sources are fetched/unpacked and S needs to follow that. Additionally for git repos it moved away from having 'git/' as the checkout directory. This has been partly tested by building weston based image for imx6/imx6ull/imx7/imx8/imx8mm/imx8mp/imx95 based images. E.g. none of the recipes specific for qoriq is built time tested. As walnascar is no longer compatible with master/whinlatter drop it from LAYERSERIES_COMPAT. [1] https://lore.kernel.org/openembedded-core/20250616095000.2918921-1-alex.kanavin@gmail.com/ Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
44 lines
1.2 KiB
BlitzBasic
44 lines
1.2 KiB
BlitzBasic
DESCRIPTION = "The Management Complex (MC) is a key component of DPAA"
|
|
SECTION = "mc-utils"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=386a6287daa6504b7e7e5014ddfb3987"
|
|
|
|
DEPENDS += "dtc-native"
|
|
|
|
inherit deploy
|
|
|
|
SRC_URI = "git://github.com/nxp-qoriq/mc-utils;protocol=https;nobranch=1"
|
|
SRCREV = "5ccc2688b72c4a05119a393cbe3573b5f81d10bc"
|
|
|
|
MC_CFG ?= ""
|
|
MC_CFG:ls1088a = "ls1088a"
|
|
MC_CFG:ls2088a = "ls2088a"
|
|
MC_CFG:lx2160a = "lx2160a"
|
|
MC_CFG:lx2162a = "lx2162a"
|
|
|
|
MC_FLAVOUR ?= "${@oe.utils.ifelse(d.getVar('MACHINE').endswith('qds'), 'QDS', 'RDB')}"
|
|
MC_FOLDER ?= "${@d.getVar('MC_CFG').upper() + '-' + d.getVar('MC_FLAVOUR')}"
|
|
|
|
do_compile () {
|
|
oe_runmake -C config
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}/boot/mc-utils
|
|
if [ -e ${S}/config/${MC_CFG}/${MC_FOLDER} ]; then
|
|
cp -r ${S}/config/${MC_CFG}/${MC_FOLDER}/* ${D}/boot/mc-utils/
|
|
fi
|
|
find ${D}/boot/mc-utils/ ! -name "*.dtb" ! -type d -exec rm {} \;
|
|
}
|
|
|
|
do_deploy () {
|
|
install -d ${DEPLOYDIR}/mc-utils
|
|
cp -r ${D}/boot/mc-utils/* ${DEPLOYDIR}/mc-utils/
|
|
}
|
|
addtask deploy after do_install
|
|
|
|
PACKAGES += "${PN}-image"
|
|
FILES:${PN}-image += "/boot"
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
COMPATIBLE_MACHINE = "(qoriq-arm64)"
|