mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-07-05 05:14:44 +02:00
b747b01501
The series [1] changed the way sources are fetched/unpacked and S needs to follow that. Additionally for git repos it moved away from having 'git/' as the checkout directory. This has been partly tested by building weston based image for imx6/imx6ull/imx7/imx8/imx8mm/imx8mp/imx95 based images. E.g. none of the recipes specific for qoriq is built time tested. As walnascar is no longer compatible with master/whinlatter drop it from LAYERSERIES_COMPAT. [1] https://lore.kernel.org/openembedded-core/20250616095000.2918921-1-alex.kanavin@gmail.com/ Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
42 lines
1.2 KiB
BlitzBasic
42 lines
1.2 KiB
BlitzBasic
SUMMARY = "Reset Configuration Word"
|
|
DESCRIPTION = "Reset Configuration Word - hardware boot-time parameters for the QorIQ targets"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=44a0d0fad189770cc022af4ac6262cbe"
|
|
|
|
DEPENDS += "tcl-native"
|
|
|
|
inherit deploy siteinfo
|
|
|
|
SRC_URI = "git://github.com/nxp-qoriq/rcw;protocol=https;nobranch=1"
|
|
SRCREV = "64abe70cf0abab053c37db460c12e367e6adf7a4"
|
|
|
|
export PYTHON = "${USRBINPATH}/python3"
|
|
|
|
M = "${@d.getVar('MACHINE').replace('-64b','').replace('-32b','').replace('-${SITEINFO_ENDIANNESS}','')}"
|
|
|
|
BOARD_TARGETS = "${M}"
|
|
BOARD_TARGETS:ls2088ardb = "${M} ${M}_rev1.1"
|
|
BOARD_TARGETS:ls1088ardb-pb = "ls1088ardb"
|
|
BOARD_TARGETS:lx2160ardb = "${M} ${M}_rev2"
|
|
BOARD_TARGETS:lx2160ardb-rev2 = "lx2160ardb_rev2"
|
|
|
|
do_compile () {
|
|
oe_runmake BOARDS="${BOARD_TARGETS}" DESTDIR=${D}/boot/rcw/
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake BOARDS="${BOARD_TARGETS}" DESTDIR=${D}/boot/rcw/ install
|
|
}
|
|
|
|
do_deploy () {
|
|
install -d ${DEPLOYDIR}/rcw
|
|
cp -r ${D}/boot/rcw/* ${DEPLOYDIR}/rcw/
|
|
}
|
|
addtask deploy after do_install
|
|
|
|
PACKAGES += "${PN}-image"
|
|
FILES:${PN}-image += "/boot"
|
|
|
|
COMPATIBLE_MACHINE = "(qoriq)"
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|