mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-07-05 05:14:44 +02:00
b747b01501
The series [1] changed the way sources are fetched/unpacked and S needs to follow that. Additionally for git repos it moved away from having 'git/' as the checkout directory. This has been partly tested by building weston based image for imx6/imx6ull/imx7/imx8/imx8mm/imx8mp/imx95 based images. E.g. none of the recipes specific for qoriq is built time tested. As walnascar is no longer compatible with master/whinlatter drop it from LAYERSERIES_COMPAT. [1] https://lore.kernel.org/openembedded-core/20250616095000.2918921-1-alex.kanavin@gmail.com/ Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
36 lines
1.6 KiB
BlitzBasic
36 lines
1.6 KiB
BlitzBasic
SUMMARY = "Vulkan Utilities and Tools"
|
|
DESCRIPTION = "Assist development by enabling developers to verify their applications correct use of the Vulkan API."
|
|
HOMEPAGE = "https://www.khronos.org/vulkan/"
|
|
BUGTRACKER = "https://github.com/KhronosGroup/Vulkan-Tools"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
SRC_URI = "git://github.com/KhronosGroup/Vulkan-Tools.git;branch=main;protocol=https"
|
|
SRCREV = "c86d42cf9eb620eeac377e3bff46ae342c5cd664"
|
|
|
|
inherit cmake features_check pkgconfig
|
|
ANY_OF_DISTRO_FEATURES = "x11 wayland"
|
|
REQUIRED_DISTRO_FEATURES = "vulkan"
|
|
|
|
DEPENDS += "vulkan-headers vulkan-loader vulkan-volk"
|
|
|
|
EXTRA_OECMAKE = "\
|
|
-DBUILD_TESTS=OFF \
|
|
-DBUILD_CUBE=OFF \
|
|
-DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3 \
|
|
"
|
|
|
|
# must choose x11 or wayland or both
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
|
|
PACKAGECONFIG[x11] = "-DBUILD_WSI_XLIB_SUPPORT=ON -DBUILD_WSI_XCB_SUPPORT=ON, -DBUILD_WSI_XLIB_SUPPORT=OFF -DBUILD_WSI_XCB_SUPPORT=OFF, libxcb libx11 libxrandr"
|
|
PACKAGECONFIG[wayland] = "-DBUILD_WSI_WAYLAND_SUPPORT=ON, -DBUILD_WSI_WAYLAND_SUPPORT=OFF, wayland"
|
|
|
|
# These recipes need to be updated in lockstep with each other:
|
|
# glslang, vulkan-headers, vulkan-loader, vulkan-tools, spirv-headers, spirv-tools
|
|
# vulkan-validation-layers, vulkan-utility-libraries.
|
|
# The tags versions should always be sdk-x.y.z, as this is what
|
|
# upstream considers a release.
|
|
UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
|