mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-07-05 05:14:44 +02:00
b747b01501
The series [1] changed the way sources are fetched/unpacked and S needs to follow that. Additionally for git repos it moved away from having 'git/' as the checkout directory. This has been partly tested by building weston based image for imx6/imx6ull/imx7/imx8/imx8mm/imx8mp/imx95 based images. E.g. none of the recipes specific for qoriq is built time tested. As walnascar is no longer compatible with master/whinlatter drop it from LAYERSERIES_COMPAT. [1] https://lore.kernel.org/openembedded-core/20250616095000.2918921-1-alex.kanavin@gmail.com/ Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
44 lines
1.6 KiB
BlitzBasic
44 lines
1.6 KiB
BlitzBasic
DESCRIPTION = "A program for testing floating-point implementation"
|
|
LICENSE = "TestFloat"
|
|
|
|
LIC_FILES_CHKSUM = "file://testfloat/testfloat.txt;beginline=87;endline=95;md5=bdb2e8111838a48015c29bd97f5b6145"
|
|
|
|
SRC_URI = " http://www.jhauser.us/arithmetic/TestFloat-2a.tar.Z;name=TestFloat \
|
|
http://www.jhauser.us/arithmetic/SoftFloat-2b.tar.Z;name=SoftFloat \
|
|
"
|
|
SRC_URI:append:qoriq-ppc = " file://SoftFloat-powerpc-1.patch \
|
|
file://TestFloat-powerpc-E500v2-SPE-1.patch \
|
|
file://Yocto-replace-COMPILE_PREFIX-gcc.patch \
|
|
"
|
|
SRC_URI[TestFloat.sha256sum] = "84d14aa42adefbda2ec9708b42946f7fa59f93689b042684bd027863481f8e4e"
|
|
SRC_URI[SoftFloat.sha256sum] = "89d14b55113a2ba8cbda7011443ba1d298d381c89d939515d56c5f18f2febf81"
|
|
|
|
S = "${UNPACKDIR}/TestFloat-2a"
|
|
|
|
do_unpack2(){
|
|
mv ${UNPACKDIR}/SoftFloat-2b ${S}/SoftFloat-2b
|
|
cd ${S}
|
|
if [ -n "$(which fromdos)" ];then
|
|
find -type f -exec fromdos {} \;
|
|
elif [ -n "$(which dos2unix)" ];then
|
|
find -type f -exec dos2unix {} \;
|
|
else
|
|
echo -e "\nERROR: command dos2unix or fromdos not found\n" && return 1
|
|
fi
|
|
}
|
|
addtask do_unpack2 after do_unpack before do_patch
|
|
|
|
do_compile(){
|
|
oe_runmake -C testfloat/powerpc-linux-gcc/ CC="${CC}" EXTRA_CFLAGS="-DTEST_KERNEL_EMU"
|
|
}
|
|
|
|
do_install(){
|
|
install -d ${D}/${bindir}
|
|
install testfloat/powerpc-linux-gcc/testfloat ${D}/${bindir}
|
|
install testfloat/powerpc-linux-gcc/testsoftfloat ${D}/${bindir}
|
|
}
|
|
|
|
COMPATIBLE_HOST:e500v2 = ".*"
|
|
COMPATIBLE_HOST ?= "(none)"
|
|
|