mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-07-19 12:59:04 +02:00
b747b01501
The series [1] changed the way sources are fetched/unpacked and S needs to follow that. Additionally for git repos it moved away from having 'git/' as the checkout directory. This has been partly tested by building weston based image for imx6/imx6ull/imx7/imx8/imx8mm/imx8mp/imx95 based images. E.g. none of the recipes specific for qoriq is built time tested. As walnascar is no longer compatible with master/whinlatter drop it from LAYERSERIES_COMPAT. [1] https://lore.kernel.org/openembedded-core/20250616095000.2918921-1-alex.kanavin@gmail.com/ Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
75 lines
1.9 KiB
BlitzBasic
75 lines
1.9 KiB
BlitzBasic
SUMMARY = "i.MX G2D Samples"
|
|
DESCRIPTION = "Set of sample applications for i.MX G2D"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=0858ec9c7a80c4a2cf16e4f825a2cc91"
|
|
|
|
DEPENDS = "cairo"
|
|
|
|
PV = "2.3+git${SRCPV}"
|
|
|
|
SRC_URI = "${GPU_G2D_SAMPLES_SRC};branch=${SRCBRANCH}"
|
|
GPU_G2D_SAMPLES_SRC ?= "git://github.com/nxp-imx/g2d-samples.git;protocol=https"
|
|
SRCBRANCH = "imx_2.3"
|
|
SRCREV = "7d12c50c07d73650b4c97906ce917aff429238f8"
|
|
|
|
inherit pkgconfig
|
|
|
|
PACKAGECONFIG ??= "${PACKAGECONFIG_IMPLEMENTATION}"
|
|
PACKAGECONFIG_IMPLEMENTATION = ""
|
|
PACKAGECONFIG_IMPLEMENTATION:imxgpu2d:imxdpu = "dpu"
|
|
PACKAGECONFIG_IMPLEMENTATION:mx95-nxp-bsp = "dpu95"
|
|
PACKAGECONFIG_IMPLEMENTATION:imxgpu2d = "gpu-drm"
|
|
PACKAGECONFIG_IMPLEMENTATION:imxgpu2d:imxfbdev = "gpu-fbdev"
|
|
PACKAGECONFIG_IMPLEMENTATION:mx93-nxp-bsp = "pxp"
|
|
|
|
PACKAGECONFIG[dpu] = " \
|
|
BUILD_IMPLEMENTATION=dpu, \
|
|
, \
|
|
imx-dpu-g2d wayland-native wayland wayland-protocols, \
|
|
, \
|
|
, \
|
|
dpu95 gpu-drm gpu-fbdev pxp"
|
|
PACKAGECONFIG[dpu95] = " \
|
|
BUILD_IMPLEMENTATION=dpu95, \
|
|
, \
|
|
imx-dpu-g2d wayland-native wayland wayland-protocols, \
|
|
, \
|
|
, \
|
|
dpu gpu-drm gpu-fbdev pxp"
|
|
PACKAGECONFIG[gpu-drm] = " \
|
|
BUILD_IMPLEMENTATION=gpu-drm, \
|
|
, \
|
|
imx-gpu-g2d wayland-native wayland wayland-protocols, \
|
|
, \
|
|
, \
|
|
dpu dpu95 gpu-fbdev pxp"
|
|
PACKAGECONFIG[gpu-fbdev] = " \
|
|
BUILD_IMPLEMENTATION=gpu-fbdev, \
|
|
, \
|
|
imx-gpu-g2d, \
|
|
, \
|
|
, \
|
|
dpu dpu95 gpu-drm pxp"
|
|
PACKAGECONFIG[pxp] = " \
|
|
BUILD_IMPLEMENTATION=pxp, \
|
|
, \
|
|
imx-pxp-g2d wayland-native wayland wayland-protocols, \
|
|
, \
|
|
, \
|
|
dpu dpu95 gpu-drm gpu-fbdev"
|
|
|
|
EXTRA_OEMAKE += " \
|
|
SDKTARGETSYSROOT=${STAGING_DIR_HOST} \
|
|
${PACKAGECONFIG_CONFARGS} \
|
|
"
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
FILES:${PN} += "/opt"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_SOCARCH}"
|
|
|
|
COMPATIBLE_MACHINE = "(imxgpu2d|mx93-nxp-bsp|mx95-nxp-bsp)"
|