mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2026-01-27 11:52:04 +01:00
2c193ca6ff
Add HOMEPAGE variable to imx-gpu-g2d recipe. Signed-off-by: Weisser, Pascal <pascal.weisser.ext@karlstorz.com>
44 lines
1.5 KiB
BlitzBasic
44 lines
1.5 KiB
BlitzBasic
# Copyright (C) 2016 Freescale Semiconductor
|
|
# Copyright 2017-2022 NXP
|
|
# Copyright 2018 (C) O.S. Systems Software LTDA.
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
DESCRIPTION = "G2D library using i.MX GPU"
|
|
HOMEPAGE = "https://www.nxp.com/"
|
|
LICENSE = "Proprietary"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a93b654673e1bc8398ed1f30e0813359"
|
|
DEPENDS = "libgal-imx"
|
|
PROVIDES = "virtual/libg2d"
|
|
|
|
SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;name=${TARGET_ARCH};fsl-eula=true"
|
|
IMX_BIN_NAME = "${BP}-${TARGET_ARCH}-${IMX_SRCREV_ABBREV}"
|
|
IMX_SRCREV_ABBREV = "3c5e429"
|
|
SRC_URI[aarch64.sha256sum] = "190bc9203e60e5de508e1dcf057b36d2c9bc3667c6972fd12f7df797e508a22d"
|
|
SRC_URI[arm.sha256sum] = "aaf9a38fe446af579b16a836bf297f8cb1b2842ca3a784bedc21e32d37271ab4"
|
|
|
|
S = "${UNPACKDIR}/${IMX_BIN_NAME}"
|
|
|
|
inherit fsl-eula-unpack
|
|
|
|
SOC_INSTALL_DIR = "SOC_INSTALL_DIR_NOT_SET"
|
|
SOC_INSTALL_DIR:mx8mm-nxp-bsp = "mx8mm"
|
|
|
|
do_install () {
|
|
install -d ${D}${libdir}
|
|
install -d ${D}${includedir}
|
|
cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
|
|
if [ -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR} ]; then
|
|
cp -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR}/*.so* ${D}${libdir}
|
|
fi
|
|
cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
|
|
}
|
|
|
|
# The packaged binaries have been stripped of debug info, so disable
|
|
# operations accordingly.
|
|
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
INHIBIT_SYSROOT_STRIP = "1"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_SOCARCH}"
|
|
COMPATIBLE_MACHINE = "(imxgpu2d)"
|