mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-10-22 23:02:20 +02:00
76f6de20d7
This commit add the following source revisions: 858ae5a1f id3v2: Don't try parsing extended header if not enough data is available a256f3bb9 update release location in SCR to correct URL 17df24937 Update release branch in SCR.txt to lf-6.12.3-1.0.0 ac80e93be playback: Improve stream list search 67e0489c4 urisourcebin: Aggregate collections from multiple parsebin 60fcf0ee3 parsebin: Store caps on parsepad as early as possible c735496eb parsebin: Don't store bogus caps on GstStream 5d6fc457f parsebin: Minor debug statement updates 7fa4272dc urisourcebin: Allow more cases for posting stream-collection 130360066 Revert "MMFMWK-9426 decodebin3: fix rtsp stream random playback fail with "No suitable plugins found"" 025f46ab4 MMFMWK-9419 glupload: Use info in in_caps to map video frames When copying input buffer to dambuf 0dcf1a0c7 MMFMWK-9433 decodebin3: workaround to fix try next decoder fail b002bf3ea Update release branch in SCR.txt to lf-6.6.52-2.2.0 Signed-off-by: Rodrigo M. Duarte <rodrigo.duarte@ossystems.com.br>
147 lines
6.0 KiB
BlitzBasic
147 lines
6.0 KiB
BlitzBasic
# This recipe is for the i.MX fork of gstreamer1.0-plugins-base. For ease of
|
|
# maintenance, the top section is a verbatim copy of an OE-core
|
|
# recipe. The second section customizes the recipe for i.MX.
|
|
|
|
########### OE-core copy ##################
|
|
# Upstream hash: 937817e5164f8af8452aec03ae3c45cb23d63df9
|
|
|
|
require gstreamer1.0-plugins-common.inc
|
|
|
|
SUMMARY = "'Base' GStreamer plugins and helper libraries"
|
|
HOMEPAGE = "https://gstreamer.freedesktop.org/"
|
|
BUGTRACKER = "https://gitlab.freedesktop.org/gstreamer/gst-plugins-base/-/issues"
|
|
LICENSE = "LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=69333daa044cb77e486cc36129f7a770"
|
|
|
|
SRC_URI = "https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \
|
|
file://0001-ENGR00312515-get-caps-from-src-pad-when-query-caps.patch \
|
|
file://0003-viv-fb-Make-sure-config.h-is-included.patch \
|
|
file://0002-ssaparse-enhance-SSA-text-lines-parsing.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "edd4338b45c26a9af28c0d35aab964a024c3884ba6f520d8428df04212c8c93a"
|
|
|
|
S = "${WORKDIR}/gst-plugins-base-${PV}"
|
|
|
|
DEPENDS += "iso-codes util-linux zlib"
|
|
|
|
inherit gobject-introspection
|
|
|
|
# opengl packageconfig factored out to make it easy for distros
|
|
# and BSP layers to choose OpenGL APIs/platforms/window systems
|
|
PACKAGECONFIG_X11 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'opengl glx', '', d)}"
|
|
PACKAGECONFIG_GL ?= "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2 egl ${PACKAGECONFIG_X11}', '', d)}"
|
|
|
|
PACKAGECONFIG ??= " \
|
|
${GSTREAMER_ORC} \
|
|
${PACKAGECONFIG_GL} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'alsa x11', d)} \
|
|
jpeg ogg pango png theora vorbis \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland egl', '', d)} \
|
|
"
|
|
|
|
OPENGL_APIS = 'opengl gles2'
|
|
OPENGL_PLATFORMS = 'egl glx'
|
|
|
|
X11DEPENDS = "virtual/libx11 libsm libxrender libxv"
|
|
X11ENABLEOPTS = "-Dx11=enabled -Dxvideo=enabled -Dxshm=enabled"
|
|
X11DISABLEOPTS = "-Dx11=disabled -Dxvideo=disabled -Dxshm=disabled"
|
|
|
|
PACKAGECONFIG[alsa] = "-Dalsa=enabled,-Dalsa=disabled,alsa-lib"
|
|
PACKAGECONFIG[cdparanoia] = "-Dcdparanoia=enabled,-Dcdparanoia=disabled,cdparanoia"
|
|
PACKAGECONFIG[graphene] = "-Dgl-graphene=enabled,-Dgl-graphene=disabled,graphene"
|
|
PACKAGECONFIG[jpeg] = "-Dgl-jpeg=enabled,-Dgl-jpeg=disabled,jpeg"
|
|
PACKAGECONFIG[ogg] = "-Dogg=enabled,-Dogg=disabled,libogg"
|
|
PACKAGECONFIG[opus] = "-Dopus=enabled,-Dopus=disabled,libopus"
|
|
PACKAGECONFIG[pango] = "-Dpango=enabled,-Dpango=disabled,pango"
|
|
PACKAGECONFIG[png] = "-Dgl-png=enabled,-Dgl-png=disabled,libpng"
|
|
# This enables Qt5 QML examples in -base. The Qt5 GStreamer
|
|
# qmlglsink and qmlglsrc plugins still exist in -good.
|
|
PACKAGECONFIG[qt5] = "-Dqt5=enabled,-Dqt5=disabled,qtbase qtdeclarative qtbase-native"
|
|
PACKAGECONFIG[theora] = "-Dtheora=enabled,-Dtheora=disabled,libtheora"
|
|
PACKAGECONFIG[tremor] = "-Dtremor=enabled,-Dtremor=disabled,tremor"
|
|
PACKAGECONFIG[visual] = "-Dlibvisual=enabled,-Dlibvisual=disabled,libvisual"
|
|
PACKAGECONFIG[vorbis] = "-Dvorbis=enabled,-Dvorbis=disabled,libvorbis"
|
|
PACKAGECONFIG[x11] = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}"
|
|
|
|
# OpenGL API packageconfigs
|
|
PACKAGECONFIG[opengl] = ",,virtual/libgl libglu"
|
|
PACKAGECONFIG[gles2] = ",,virtual/libgles2"
|
|
|
|
# OpenGL platform packageconfigs
|
|
PACKAGECONFIG[egl] = ",,virtual/egl"
|
|
PACKAGECONFIG[glx] = ",,virtual/libgl"
|
|
|
|
# OpenGL window systems (except for X11)
|
|
PACKAGECONFIG[gbm] = ",,virtual/libgbm libgudev libdrm"
|
|
PACKAGECONFIG[wayland] = ",,wayland-native wayland wayland-protocols libdrm"
|
|
PACKAGECONFIG[dispmanx] = ",,virtual/libomxil"
|
|
PACKAGECONFIG[viv-fb] = ",,virtual/libgles2 virtual/libg2d"
|
|
|
|
OPENGL_WINSYS = "${@bb.utils.filter('PACKAGECONFIG', 'x11 gbm wayland dispmanx egl viv-fb', d)}"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Ddoc=disabled \
|
|
${@get_opengl_cmdline_list('gl_api', d.getVar('OPENGL_APIS'), d)} \
|
|
${@get_opengl_cmdline_list('gl_platform', d.getVar('OPENGL_PLATFORMS'), d)} \
|
|
${@get_opengl_cmdline_list('gl_winsys', d.getVar('OPENGL_WINSYS'), d)} \
|
|
"
|
|
|
|
FILES:${PN}-dev += "${libdir}/gstreamer-1.0/include/gst/gl/gstglconfig.h"
|
|
FILES:${MLPREFIX}libgsttag-1.0 += "${datadir}/gst-plugins-base/1.0/license-translations.dict"
|
|
|
|
def get_opengl_cmdline_list(switch_name, options, d):
|
|
selected_options = []
|
|
if bb.utils.contains('DISTRO_FEATURES', 'opengl', True, False, d):
|
|
for option in options.split():
|
|
if bb.utils.contains('PACKAGECONFIG', option, True, False, d):
|
|
selected_options += [option]
|
|
if selected_options:
|
|
return '-D' + switch_name + '=' + ','.join(selected_options)
|
|
else:
|
|
return ''
|
|
|
|
CVE_PRODUCT += "gst-plugins-base"
|
|
|
|
########### End of OE-core copy ###########
|
|
|
|
########### i.MX overrides ################
|
|
|
|
DEFAULT_PREFERENCE = "-1"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=69333daa044cb77e486cc36129f7a770"
|
|
|
|
SRC_URI:remove = " \
|
|
https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \
|
|
file://0001-ENGR00312515-get-caps-from-src-pad-when-query-caps.patch \
|
|
file://0003-viv-fb-Make-sure-config.h-is-included.patch \
|
|
file://0002-ssaparse-enhance-SSA-text-lines-parsing.patch"
|
|
SRC_URI:prepend = "${GST1.0-PLUGINS-BASE_SRC};branch=${SRCBRANCH} "
|
|
|
|
GST1.0-PLUGINS-BASE_SRC ?= "gitsm://github.com/nxp-imx/gst-plugins-base.git;protocol=https"
|
|
SRCBRANCH = "MM_04.09.03_2412_L6.12.y"
|
|
SRCREV = "858ae5a1fb2bd2692ca7ebbd5bde2eee14e1842d"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit use-imx-headers
|
|
|
|
PACKAGECONFIG:remove = "${PACKAGECONFIG_REMOVE}"
|
|
PACKAGECONFIG_REMOVE ?= "jpeg"
|
|
|
|
PACKAGECONFIG:append = " ${PACKAGECONFIG_G2D}"
|
|
PACKAGECONFIG_G2D ??= ""
|
|
PACKAGECONFIG_G2D:imxgpu2d ??= "g2d"
|
|
|
|
PACKAGECONFIG[g2d] = ",,virtual/libg2d"
|
|
PACKAGECONFIG[viv-fb] = ",,virtual/libgles2"
|
|
|
|
EXTRA_OEMESON += "-Dc_args="${CFLAGS} -I${STAGING_INCDIR_IMX}""
|
|
|
|
# links with imx-gpu libs which are pre-built for glibc
|
|
# gcompat will address it during runtime
|
|
LDFLAGS:append:imxgpu:libc-musl = " -Wl,--allow-shlib-undefined"
|
|
|
|
COMPATIBLE_MACHINE = "(imx-nxp-bsp)"
|
|
|
|
########### End of i.MX overrides #########
|