mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-10-22 23:02:20 +02:00
832da37d74
Since OE-Core commit 9379f80f48 ("license/insane: Show warning for
obsolete license usage"), LICENSE field not containing SPDX identifiers
are treated with WARNING.
An automated conversion using scripts/contrib/convert-spdx-licenses.py to
convert to use the standard SPDX license identifiers has been done on
the entire layer.
Signed-off-by: Andrey Zhizhikin <andrey.z@gmail.com>
80 lines
2.3 KiB
BlitzBasic
80 lines
2.3 KiB
BlitzBasic
# Copyright 2017-2021 NXP
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "Installs i.MX-specific kernel headers"
|
|
DESCRIPTION = "Installs i.MX-specific kernel headers to userspace. \
|
|
New headers are installed in ${includedir}/imx."
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
|
|
SRCBRANCH = "lf-5.10.y"
|
|
LOCALVERSION = "-5.10.72-2.2.0"
|
|
SRC_URI = "git://source.codeaurora.org/external/imx/linux-imx.git;protocol=https;branch=${SRCBRANCH}"
|
|
SRCREV = "a68e31b63f864ff71cd4adb40fbc9e1edc75c250"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
do_compile[noexec] = "1"
|
|
|
|
IMX_UAPI_HEADERS = " \
|
|
dma-buf.h \
|
|
hantrodec.h \
|
|
hx280enc.h \
|
|
ion.h \
|
|
ipu.h \
|
|
isl29023.h \
|
|
imx_vpu.h \
|
|
mxc_asrc.h \
|
|
mxc_dcic.h \
|
|
mxc_mlb.h \
|
|
mxc_sim_interface.h \
|
|
mxc_v4l2.h \
|
|
mxcfb.h \
|
|
pxp_device.h \
|
|
pxp_dma.h \
|
|
version.h \
|
|
videodev2.h \
|
|
"
|
|
|
|
do_install() {
|
|
# We install all headers inside of B so we can copy only the
|
|
# whitelisted ones, and there is no risk of a new header to be
|
|
# installed by mistake.
|
|
oe_runmake headers_install INSTALL_HDR_PATH=${B}${exec_prefix}
|
|
|
|
# Kernel should not be exporting this header
|
|
rm -f ${D}${exec_prefix}/include/scsi/scsi.h
|
|
|
|
# The ..install.cmd conflicts between various configure runs
|
|
find ${D}${includedir} -name ..install.cmd | xargs rm -f
|
|
|
|
# FIXME: The ion.h is still on staging so "promote" it for now
|
|
cp ${S}/drivers/staging/android/uapi/ion.h ${B}${includedir}/linux
|
|
|
|
# Install whitelisted headers only
|
|
for h in ${IMX_UAPI_HEADERS}; do
|
|
install -D -m 0644 ${B}${includedir}/linux/$h \
|
|
${D}${includedir}/imx/linux/$h
|
|
done
|
|
}
|
|
|
|
# Allow to build empty main package, this is required in order for -dev package
|
|
# to be propagated into the SDK
|
|
#
|
|
# Without this setting the RDEPENDS in other recipes fails to find this
|
|
# package, therefore causing the -dev package also to be skipped effectively not
|
|
# populating it into SDK
|
|
ALLOW_EMPTY:${PN} = "1"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS += "unifdef-native bison-native rsync-native"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_SOCARCH}"
|
|
|
|
# Restrict this recipe to NXP BSP only, this recipe is not compatible
|
|
# with mainline BSP
|
|
COMPATIBLE_HOST = '(null)'
|
|
COMPATIBLE_HOST:use-nxp-bsp = '.*'
|