mirror of
git://git.yoctoproject.org/meta-freescale.git
synced 2025-10-22 14:52:19 +02:00
0688f79193
Rework imx-boot and use-imx-security-controller-firmware.bbclass with a generic SOC revision design implemented in imx-base.inc. This does replace the machine feature design using `soc-rev*`, but maintains backwards compatibility by incorporating that design into the default settings. Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>
266 lines
11 KiB
BlitzBasic
266 lines
11 KiB
BlitzBasic
# Copyright (C) 2017-2020 NXP
|
|
|
|
require imx-mkimage_git.inc
|
|
|
|
DESCRIPTION = "Generate Boot Loader for i.MX 8 device"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0-only;md5=801f80980d171dd6425610833a22dbe6"
|
|
SECTION = "BSP"
|
|
|
|
inherit use-imx-security-controller-firmware uboot-sign
|
|
|
|
DEPENDS += " \
|
|
u-boot \
|
|
${IMX_EXTRA_FIRMWARE} \
|
|
imx-atf \
|
|
${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'optee-os', '', d)} \
|
|
"
|
|
# xxd is a dependency of fspi_packer.sh
|
|
DEPENDS += "xxd-native"
|
|
DEPENDS:append:mx8m-generic-bsp = " u-boot-mkimage-native dtc-native"
|
|
BOOT_NAME = "imx-boot"
|
|
PROVIDES = "${BOOT_NAME}"
|
|
|
|
inherit deploy uuu_bootloader_tag
|
|
|
|
UUU_BOOTLOADER = "${BOOT_NAME}"
|
|
UUU_BOOTLOADER_TAGGED = "${BOOT_NAME}-tagged"
|
|
|
|
# Add CFLAGS with native INCDIR & LIBDIR for imx-mkimage build
|
|
CFLAGS = "-O2 -Wall -std=c99 -I ${STAGING_INCDIR_NATIVE} -L ${STAGING_LIBDIR_NATIVE}"
|
|
|
|
# This package aggregates output deployed by other packages,
|
|
# so set the appropriate dependencies
|
|
do_compile[depends] += " \
|
|
virtual/bootloader:do_deploy \
|
|
${@' '.join('%s:do_deploy' % r for r in '${IMX_EXTRA_FIRMWARE}'.split() )} \
|
|
imx-atf:do_deploy \
|
|
${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'optee-os:do_deploy', '', d)} \
|
|
"
|
|
|
|
SC_FIRMWARE_NAME ?= "scfw_tcm.bin"
|
|
|
|
ATF_MACHINE_NAME ?= "bl31-${ATF_PLATFORM}.bin"
|
|
ATF_MACHINE_NAME:append = "${@bb.utils.contains('MACHINE_FEATURES', 'optee', '-optee', '', d)}"
|
|
|
|
UBOOT_NAME = "u-boot-${MACHINE}.bin-${UBOOT_CONFIG}"
|
|
BOOT_CONFIG_MACHINE = "${BOOT_NAME}-${MACHINE}-${UBOOT_CONFIG}.bin"
|
|
|
|
TOOLS_NAME ?= "mkimage_imx8"
|
|
|
|
IMX_BOOT_SOC_TARGET ?= "INVALID"
|
|
|
|
DEPLOY_OPTEE = "${@bb.utils.contains('MACHINE_FEATURES', 'optee', 'true', 'false', d)}"
|
|
|
|
IMXBOOT_TARGETS ?= \
|
|
"${@bb.utils.contains('UBOOT_CONFIG', 'fspi', 'flash_flexspi', \
|
|
bb.utils.contains('UBOOT_CONFIG', 'nand', 'flash_nand', \
|
|
'flash_multi_cores flash_dcd', d), d)}"
|
|
|
|
BOOT_STAGING = "${S}/${IMX_BOOT_SOC_TARGET}"
|
|
BOOT_STAGING:mx8m-generic-bsp = "${S}/iMX8M"
|
|
BOOT_STAGING:mx8dx-generic-bsp = "${S}/iMX8QX"
|
|
|
|
SOC_FAMILY = "INVALID"
|
|
SOC_FAMILY:mx8-generic-bsp = "mx8"
|
|
SOC_FAMILY:mx8m-generic-bsp = "mx8m"
|
|
SOC_FAMILY:mx8x-generic-bsp = "mx8x"
|
|
SOC_FAMILY:mx8ulp-generic-bsp = "mx8ulp"
|
|
SOC_FAMILY:mx93-generic-bsp = "mx93"
|
|
|
|
REV_OPTION ?= "REV=${IMX_SOC_REV_UPPER}"
|
|
|
|
do_uboot_assemble_fitimage:prepend:imx-generic-bsp() {
|
|
for config in ${UBOOT_MACHINE}; do
|
|
mkdir -p ${B}/${config}
|
|
done
|
|
}
|
|
|
|
compile_mx8m() {
|
|
bbnote 8MQ/8MM/8MN/8MP boot binary build
|
|
for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
|
|
bbnote "Copy ddr_firmware: ${ddr_firmware} from ${DEPLOY_DIR_IMAGE} -> ${BOOT_STAGING} "
|
|
cp ${DEPLOY_DIR_IMAGE}/${ddr_firmware} ${BOOT_STAGING}
|
|
done
|
|
cp ${DEPLOY_DIR_IMAGE}/signed_dp_imx8m.bin ${BOOT_STAGING}
|
|
cp ${DEPLOY_DIR_IMAGE}/signed_hdmi_imx8m.bin ${BOOT_STAGING}
|
|
cp ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${BOOT_STAGING}/u-boot-spl.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${UBOOT_DTB_NAME} ${BOOT_STAGING}
|
|
if [ "x${UBOOT_SIGN_ENABLE}" = "x1" ] ; then
|
|
# Use DTB binary patched with signature node
|
|
cp ${DEPLOY_DIR_IMAGE}/${UBOOT_DTB_BINARY} ${BOOT_STAGING}/${UBOOT_DTB_NAME}
|
|
fi
|
|
cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/u-boot-nodtb.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${BOOT_STAGING}/u-boot-nodtb.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${ATF_MACHINE_NAME} ${BOOT_STAGING}/bl31.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${BOOT_STAGING}/u-boot.bin
|
|
}
|
|
compile_mx8() {
|
|
bbnote 8QM boot binary build
|
|
cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${SC_FIRMWARE_NAME} ${BOOT_STAGING}/scfw_tcm.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${ATF_MACHINE_NAME} ${BOOT_STAGING}/bl31.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${BOOT_STAGING}/u-boot.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${SECO_FIRMWARE_NAME} ${BOOT_STAGING}
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
cp ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${BOOT_STAGING}/u-boot-spl.bin
|
|
fi
|
|
}
|
|
|
|
compile_mx8x() {
|
|
bbnote 8QX boot binary build
|
|
cp ${DEPLOY_DIR_IMAGE}/${SECO_FIRMWARE_NAME} ${BOOT_STAGING}
|
|
cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/${SC_FIRMWARE_NAME} ${BOOT_STAGING}/scfw_tcm.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${ATF_MACHINE_NAME} ${BOOT_STAGING}/bl31.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${BOOT_STAGING}/u-boot.bin
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
cp ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${BOOT_STAGING}/u-boot-spl.bin
|
|
fi
|
|
}
|
|
|
|
compile_mx8ulp() {
|
|
bbnote 8ULP boot binary build
|
|
cp ${DEPLOY_DIR_IMAGE}/${SECO_FIRMWARE_NAME} ${BOOT_STAGING}/
|
|
cp ${DEPLOY_DIR_IMAGE}/${ATF_MACHINE_NAME} ${BOOT_STAGING}/bl31.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${BOOT_TOOLS}/upower.bin ${BOOT_STAGING}/upower.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${BOOT_STAGING}/u-boot.bin
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
cp ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${BOOT_STAGING}/u-boot-spl.bin
|
|
fi
|
|
}
|
|
|
|
compile_mx93() {
|
|
bbnote i.MX 93 boot binary build
|
|
for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
|
|
bbnote "Copy ddr_firmware: ${ddr_firmware} from ${DEPLOY_DIR_IMAGE} -> ${BOOT_STAGING} "
|
|
cp ${DEPLOY_DIR_IMAGE}/${ddr_firmware} ${BOOT_STAGING}
|
|
done
|
|
|
|
cp ${DEPLOY_DIR_IMAGE}/${SECO_FIRMWARE_NAME} ${BOOT_STAGING}/
|
|
cp ${DEPLOY_DIR_IMAGE}/${ATF_MACHINE_NAME} ${BOOT_STAGING}/bl31.bin
|
|
cp ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${BOOT_STAGING}/u-boot.bin
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
cp ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${BOOT_STAGING}/u-boot-spl.bin
|
|
fi
|
|
}
|
|
|
|
do_compile() {
|
|
# mkimage for i.MX8
|
|
# Copy TEE binary to SoC target folder to mkimage
|
|
if ${DEPLOY_OPTEE}; then
|
|
cp ${DEPLOY_DIR_IMAGE}/tee.bin ${BOOT_STAGING}
|
|
fi
|
|
for target in ${IMXBOOT_TARGETS}; do
|
|
compile_${SOC_FAMILY}
|
|
if [ "$target" = "flash_linux_m4_no_v2x" ]; then
|
|
# Special target build for i.MX 8DXL with V2X off
|
|
bbnote "building ${IMX_BOOT_SOC_TARGET} - ${REV_OPTION} V2X=NO ${target}"
|
|
make SOC=${IMX_BOOT_SOC_TARGET} ${REV_OPTION} V2X=NO dtbs=${UBOOT_DTB_NAME} flash_linux_m4
|
|
else
|
|
bbnote "building ${IMX_BOOT_SOC_TARGET} - ${REV_OPTION} ${target}"
|
|
make SOC=${IMX_BOOT_SOC_TARGET} ${REV_OPTION} dtbs=${UBOOT_DTB_NAME} ${target}
|
|
fi
|
|
if [ -e "${BOOT_STAGING}/flash.bin" ]; then
|
|
cp ${BOOT_STAGING}/flash.bin ${S}/${BOOT_CONFIG_MACHINE}-${target}
|
|
fi
|
|
done
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}/boot
|
|
for target in ${IMXBOOT_TARGETS}; do
|
|
install -m 0644 ${S}/${BOOT_CONFIG_MACHINE}-${target} ${D}/boot/
|
|
done
|
|
}
|
|
|
|
deploy_mx8m() {
|
|
install -d ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${DEPLOYDIR}/${BOOT_TOOLS}
|
|
for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/${ddr_firmware} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
done
|
|
install -m 0644 ${BOOT_STAGING}/signed_dp_imx8m.bin ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0644 ${BOOT_STAGING}/signed_hdmi_imx8m.bin ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0755 ${BOOT_STAGING}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0755 ${BOOT_STAGING}/mkimage_fit_atf.sh ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
}
|
|
deploy_mx8() {
|
|
install -d ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0644 ${BOOT_STAGING}/${SECO_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0755 ${S}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${DEPLOYDIR}/${BOOT_TOOLS}
|
|
fi
|
|
}
|
|
deploy_mx8x() {
|
|
install -d ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0644 ${BOOT_STAGING}/${SECO_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0755 ${S}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${DEPLOYDIR}/${BOOT_TOOLS}
|
|
fi
|
|
}
|
|
|
|
deploy_mx8ulp() {
|
|
install -d ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0644 ${BOOT_STAGING}/${SECO_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0755 ${S}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${DEPLOYDIR}/${BOOT_TOOLS}
|
|
fi
|
|
}
|
|
|
|
deploy_mx93() {
|
|
install -d ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
|
|
for ddr_firmware in ${DDR_FIRMWARE_NAME}; do
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/${ddr_firmware} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
done
|
|
|
|
install -m 0644 ${BOOT_STAGING}/${SECO_FIRMWARE_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
install -m 0755 ${S}/${TOOLS_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
if [ -e ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} ] ; then
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/u-boot-spl.bin-${MACHINE}-${UBOOT_CONFIG} \
|
|
${DEPLOYDIR}/${BOOT_TOOLS}
|
|
fi
|
|
}
|
|
|
|
do_deploy() {
|
|
deploy_${SOC_FAMILY}
|
|
# copy the sc fw, dcd and uboot to deploy path
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/${UBOOT_NAME} ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
|
|
# copy tee.bin to deploy path
|
|
if ${DEPLOY_OPTEE}; then
|
|
install -m 0644 ${DEPLOY_DIR_IMAGE}/tee.bin ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
fi
|
|
|
|
# copy makefile (soc.mak) for reference
|
|
install -m 0644 ${BOOT_STAGING}/soc.mak ${DEPLOYDIR}/${BOOT_TOOLS}
|
|
# copy the generated boot image to deploy path
|
|
for target in ${IMXBOOT_TARGETS}; do
|
|
# Use first "target" as IMAGE_IMXBOOT_TARGET
|
|
if [ "$IMAGE_IMXBOOT_TARGET" = "" ]; then
|
|
IMAGE_IMXBOOT_TARGET="$target"
|
|
echo "Set boot target as $IMAGE_IMXBOOT_TARGET"
|
|
fi
|
|
install -m 0644 ${S}/${BOOT_CONFIG_MACHINE}-${target} ${DEPLOYDIR}
|
|
done
|
|
|
|
ln -sf ${BOOT_CONFIG_MACHINE}-${IMAGE_IMXBOOT_TARGET} ${DEPLOYDIR}/${BOOT_NAME}
|
|
}
|
|
addtask deploy before do_build after do_compile
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
FILES:${PN} = "/boot"
|
|
|
|
COMPATIBLE_MACHINE = "(mx8-generic-bsp|mx9-generic-bsp)"
|