mirror of
https://github.com/nxp-imx/meta-imx.git
synced 2025-10-22 15:22:15 +02:00
2f05c25d07
The NXP BSP is moving from CAF to github, so update the recipes URLs and set PREMIRRORS to override the SRC_URIs. Also update the paths to point to git.codelinaro.org Signed-off-by: Valentin Jec <jec.valentin@nxp.com>
71 lines
2.5 KiB
BlitzBasic
71 lines
2.5 KiB
BlitzBasic
# Copyright (C) 2013-2016 Freescale Semiconductor
|
|
# Copyright 2017-2019 NXP
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "Linux Kernel provided and supported by NXP"
|
|
DESCRIPTION = "Linux Kernel provided and supported by NXP with focus on \
|
|
i.MX Family Reference Boards. It includes support for many IPs such as GPU, VPU and IPU."
|
|
|
|
require recipes-kernel/linux/linux-imx.inc
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"
|
|
|
|
DEPENDS += "lzop-native bc-native"
|
|
|
|
KERNEL_BRANCH ?= "imx_5.4.3_2.0.0"
|
|
LOCALVERSION = "-2.0.0"
|
|
KERNEL_SRC ?= "git://github.com/nxp-imx/linux-imx.git;protocol=https"
|
|
SRC_URI = "${KERNEL_SRC};branch=${KERNEL_BRANCH}"
|
|
|
|
SRCREV = "fd263a3edd95dfe812397fabf1059b5f99bba2ab"
|
|
|
|
FILES_${KERNEL_PACKAGE_NAME}-base += "${nonarch_base_libdir}/modules/${KERNEL_VERSION}/modules.builtin.modinfo "
|
|
|
|
KERNEL_CONFIG_COMMAND = "oe_runmake_call -C ${S} CC="${KERNEL_CC}" O=${B} olddefconfig"
|
|
|
|
FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
|
|
|
|
DEFAULT_PREFERENCE = "1"
|
|
|
|
DO_CONFIG_V7_COPY = "no"
|
|
DO_CONFIG_V7_COPY_mx6 = "yes"
|
|
DO_CONFIG_V7_COPY_mx7 = "yes"
|
|
DO_CONFIG_V7_COPY_mx8 = "no"
|
|
|
|
addtask copy_defconfig after do_unpack before do_preconfigure
|
|
do_copy_defconfig () {
|
|
install -d ${B}
|
|
if [ ${DO_CONFIG_V7_COPY} = "yes" ]; then
|
|
# copy latest imx_v7_defconfig to use for mx6, mx6ul and mx7
|
|
mkdir -p ${B}
|
|
cp ${S}/arch/arm/configs/imx_v7_defconfig ${B}/.config
|
|
cp ${S}/arch/arm/configs/imx_v7_defconfig ${B}/../defconfig
|
|
else
|
|
# copy latest imx_v8_defconfig to use for mx8
|
|
mkdir -p ${B}
|
|
cp ${S}/arch/arm64/configs/imx_v8_defconfig ${B}/.config
|
|
cp ${S}/arch/arm64/configs/imx_v8_defconfig ${B}/../defconfig
|
|
fi
|
|
}
|
|
|
|
DELTA_KERNEL_DEFCONFIG ?= ""
|
|
#DELTA_KERNEL_DEFCONFIG_prepend_mx8 = "sdk_imx.config "
|
|
|
|
do_merge_delta_config[dirs] = "${B}"
|
|
do_merge_delta_config() {
|
|
for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
|
|
if [ -f ${S}/arch/${ARCH}/configs/${deltacfg} ]; then
|
|
${KERNEL_CONFIG_COMMAND}
|
|
oe_runmake_call -C ${S} CC="${KERNEL_CC}" O=${B} ${deltacfg}
|
|
elif [ -f "${WORKDIR}/${deltacfg}" ]; then
|
|
${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
|
|
elif [ -f "${deltacfg}" ]; then
|
|
${S}/scripts/kconfig/merge_config.sh -m .config ${deltacfg}
|
|
fi
|
|
done
|
|
cp .config ${WORKDIR}/defconfig
|
|
}
|
|
addtask merge_delta_config before do_preconfigure after do_copy_defconfig
|
|
|
|
COMPATIBLE_MACHINE = "(mx6|mx7|mx8)"
|