libvpl-tools: add 1.0.0 version

Command line tools application that remove from libvpl
start from 2.11.0 version.

Release notes:
https://github.com/intel/libvpl-tools/releases/tag/v1.0.0

Signed-off-by: Lim Siew Hoon <siew.hoon.lim@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

recipes-multimedia/vpl/libvpl-tools_1.0.0.bb

@@ -0,0 +1,39 @@
+SUMMARY = "Intel Video Processing Library Tools"
+DESCRIPTION = "Intel Video Processing Library (VPL) Tools provides \
+access to hardware accelerated video decode, encode and video processing \
+capabilities on Intel® GPUs use cases."
+
+HOMEPAGE = "https://github.com/intel/libvpl-tools"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c18ea6bb4786a26bf4eee88a7424a408 \
+                    file://third-party-programs.txt;md5=ddf05049184e74942f45b0ca4cc69b8a"
+
+SRC_URI = "git://github.com/intel/libvpl-tools.git;protocol=https;branch=main \
+          "
+
+SRCREV = "452ab253da13b57067222e8311ef143d0203d766"
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "libva libvpl pkgconfig-native"
+
+PACKAGECONFIG ??= "tools"
+PACKAGECONFIG[tools] = "-DENABLE_WAYLAND=ON, -DENABLE_WAYLAND=OFF, wayland wayland-native wayland-protocols"
+
+do_install:append() {
+        mkdir -p ${D}${datadir}/VPL/samples
+        mv ${D}${bindir}/sample_* ${D}${datadir}/VPL/samples
+        mv ${D}${bindir}/metrics_monitor ${D}${datadir}/VPL/samples
+}
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+
+FILES_SOLIBSDEV = ""
+
+FILES:${PN} += " ${datadir}/VPL/samples  \
+                 ${libdir}/libcttmetrics.so \
+                 ${libdir}/vpl-tools/libvpl_wayland.so \
+                "
+
+FILES:${PN}-doc += " ${datadir}/vpl-tools \
+                   "