opencl-clang: add recipe for LLVM 11

Point to latest for llvm 11 branch as there's no official release yet.
And, pick the version of opencl-clang based on LLVMVERSION.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

conf/machine/include/meta-intel.inc

@@ -26,6 +26,9 @@ PREFERRED_PROVIDER_libva-utils = "libva-utils-intel"
 PREFERRED_PROVIDER_libva-native = "libva-utils-intel-native"
 PREFERRED_PROVIDER_nativesdk-libva-utils = "nativesdk-libva-utils-intel"
 
+PREFERRED_VERSION_opencl-clang ?= "${@bb.utils.contains('LLVMVERSION', '10.0.1', '10.0.0', '11.0.0', d)}"
+PREFERRED_VERSION_opencl-clang-native ?= "${@bb.utils.contains('LLVMVERSION', '10.0.1', '10.0.0', '11.0.0', d)}"
+
 XSERVER_X86_ASPEED_AST = "xf86-video-ast \
            "
 

dynamic-layers/clang-layer/recipes-opencl/opencl-clang/opencl-clang_11.0.0.bb

@@ -0,0 +1,34 @@
+SUMMARY = "Common clang is a thin wrapper library around clang"
+DESCRIPTION = "Common clang has OpenCL-oriented API and is capable \
+ to compile OpenCL C kernels to SPIR-V modules."
+
+LICENSE = "NCSA"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e8a15bf1416762a09ece07e44c79118c"
+
+SRC_URI = "git://github.com/intel/opencl-clang.git;branch=ocl-open-110;protocol=https \
+           file://0001-don-t-redefine-LLVM_TABLEGEN_EXE.patch \
+           "
+SRC_URI_append_class-native = " file://0002-make-sure-only-static-libraries-linked-for-native-bu.patch"
+
+SRCREV = "7fa38fff412e6fbfa5385a3c135e4d5216b9ab17"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+DEPENDS += "clang"
+DEPENDS_append_class-target = " opencl-clang-native"
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST_libc-musl = "null"
+
+EXTRA_OECMAKE += "\
+                  -DLLVM_TABLEGEN_EXE=${STAGING_BINDIR_NATIVE}/llvm-tblgen \
+                  -DCMAKE_SKIP_RPATH=TRUE \
+                  "
+
+do_install_append_class-native() {
+        install -d ${D}${bindir}
+        install -m 0755 ${B}/linux_linker/linux_resource_linker ${D}${bindir}/
+}
+
+BBCLASSEXTEND = "native nativesdk"