mirror of
git://git.yoctoproject.org/meta-intel.git
synced 2025-07-19 12:59:03 +02:00
0584f63879
Use the convert-overrides.py to convert to new syntax and manually fix some additional changes. Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
57 lines
1.8 KiB
BlitzBasic
57 lines
1.8 KiB
BlitzBasic
SUMMARY = "The Intel(R) Graphics Compute Runtime for OpenCL(TM)"
|
|
DESCRIPTION = "The Intel(R) Graphics Compute Runtime for OpenCL(TM) \
|
|
is an open source project to converge Intel's development efforts \
|
|
on OpenCL(TM) compute stacks supporting the GEN graphics hardware \
|
|
architecture."
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=ae27f47fd6755510247c19e547e4c804 \
|
|
file://third_party/opencl_headers/LICENSE;md5=dcefc90f4c3c689ec0c2489064e7273b"
|
|
|
|
SRC_URI = "git://github.com/intel/compute-runtime.git;protocol=https \
|
|
"
|
|
SRC_URI:append:class-target = " file://allow-to-find-cpp-generation-tool.patch"
|
|
|
|
SRCREV = "5a05d7643c4d8cc14e281b686c78101a7a01e8e1"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS += " intel-graphics-compiler gmmlib"
|
|
DEPENDS:append:class-target = " intel-compute-runtime-native libva"
|
|
|
|
RDEPENDS:${PN} += " intel-graphics-compiler gmmlib"
|
|
|
|
inherit cmake pkgconfig
|
|
|
|
COMPATIBLE_HOST = '(x86_64).*-linux'
|
|
COMPATIBLE_HOST:libc-musl = "null"
|
|
|
|
EXTRA_OECMAKE = " \
|
|
-DIGC_DIR=${STAGING_INCDIR}/igc \
|
|
-DBUILD_TYPE=Release \
|
|
-DSKIP_UNIT_TESTS=1 \
|
|
-DCCACHE_ALLOWED=FALSE \
|
|
"
|
|
EXTRA_OECMAKE:append:class-target = " \
|
|
-Dcloc_cmd_prefix=ocloc \
|
|
"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[levelzero] = "-DBUILD_WITH_L0=ON, -DBUILD_WITH_L0=OFF, level-zero"
|
|
|
|
do_install:append:class-native() {
|
|
install -d ${D}${bindir}
|
|
install ${B}/bin/cpp_generate_tool ${D}${bindir}/
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${libdir}/intel-opencl/libigdrcl.so \
|
|
${libdir}/libocloc.so \
|
|
"
|
|
|
|
FILES:${PN}-dev = "${includedir}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
|