mirror of
git://git.yoctoproject.org/meta-intel.git
synced 2025-07-05 05:04:45 +02:00
cb85578bf3
* Use LTS 6.12 for RT as well, as 6.12 now has a single branch for both RT and non-RT kernels. * Rename the patch: linux-intel/0001-6.11-6.12-lib-build_OID_registry-fix-reproducibility-issues.patch * Drop the following patches, as they were specific to the 6.6 kernel: 0001-6.6-lib-build_OID_registry-fix-reproducibility-issues.patch 0001-6.6-vt-conmakehash-improve-reproducibility.patch Signed-off-by: Yogesh Tyagi <yogesh.tyagi@intel.com> Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
36 lines
1.4 KiB
BlitzBasic
36 lines
1.4 KiB
BlitzBasic
require linux-intel.inc
|
|
|
|
SRC_URI:prepend = "git://github.com/intel/linux-intel-lts.git;protocol=https;name=machine;branch=${KBRANCH}; \
|
|
"
|
|
SRC_URI:append = " file://0001-6.12-lib-build_OID_registry-fix-reproducibility-issues.patch \
|
|
"
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
|
# to build multiple virtual/kernel providers, e.g. as dependency of
|
|
# core-image-rt-sdk, core-image-rt.
|
|
python () {
|
|
if d.getVar("KERNEL_PACKAGE_NAME", True) == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-intel-rt":
|
|
raise bb.parse.SkipPackage("Set PREFERRED_PROVIDER_virtual/kernel to linux-intel-rt to enable it")
|
|
}
|
|
|
|
KBRANCH = "6.12/linux"
|
|
KMETA_BRANCH = "yocto-6.12"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
|
|
DEPENDS += "elfutils-native openssl-native util-linux-native"
|
|
|
|
LINUX_VERSION_EXTENSION ??= "-intel-pk-${LINUX_KERNEL_TYPE}"
|
|
|
|
LINUX_VERSION ?= "6.12.16"
|
|
SRCREV_machine ?= "934bc38849dd7c6cabd8110d3ef2bd50a7fc79c4"
|
|
SRCREV_meta ?= "f24c58a63b7e047d2c4441dd2adc30de21c8814d"
|
|
|
|
LINUX_KERNEL_TYPE = "preempt-rt"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/security/security.scc"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "^lts-(?P<pver>v6.12.(\d+)-linux-(\d+)T(\d+)Z)$"
|