mirror of
git://git.yoctoproject.org/meta-intel.git
synced 2025-07-19 21:09:03 +02:00
f50328b877
Fixes: | /poky/build/tmp/work/corei7-64-poky-linux/intel-compute-runtime/24.13.29138.7/git/shared/test/unit_test/gmm_helper/gmm_resource_info_tests.cpp:75:41: error: no matching function for call to 'find(std::vector<char*>::iterator, std::vector<char*>::iterator, void*&)' | 75 | EXPECT_NE(destroyed.end(), std::find(destroyed.begin(), destroyed.end(), handle)); | | ~~~~~~~~~^~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
66 lines
2.3 KiB
BlitzBasic
66 lines
2.3 KiB
BlitzBasic
SUMMARY = "The Intel(R) Graphics Compute Runtime for OpenCL(TM)"
|
|
DESCRIPTION = "The Intel(R) Graphics Compute Runtime for OpenCL(TM) \
|
|
is an open source project to converge Intel's development efforts \
|
|
on OpenCL(TM) compute stacks supporting the GEN graphics hardware \
|
|
architecture."
|
|
|
|
LICENSE = "MIT & Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.md;md5=eca6ec6997e18db166db7109cdbe611c \
|
|
file://third_party/opencl_headers/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
SRC_URI = "git://github.com/intel/compute-runtime.git;protocol=https;branch=releases/24.13 \
|
|
file://disable-werror.patch \
|
|
file://allow-to-find-cpp-generation-tool.patch \
|
|
file://external-ocloc.patch \
|
|
file://f10439aea214984a060566831f63d3aa198ef1b8.patch \
|
|
"
|
|
|
|
SRCREV = "7131387cdbb02d480a225c70daef913a6c024a6e"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS += " intel-graphics-compiler gmmlib libva qemu-native"
|
|
|
|
RDEPENDS:${PN} += " intel-graphics-compiler gmmlib"
|
|
|
|
inherit cmake pkgconfig qemu
|
|
|
|
COMPATIBLE_HOST = '(x86_64).*-linux'
|
|
COMPATIBLE_HOST:libc-musl = "null"
|
|
|
|
EXTRA_OECMAKE = " \
|
|
-DIGC_DIR=${STAGING_INCDIR}/igc \
|
|
-DBUILD_TYPE=Release \
|
|
-DSKIP_UNIT_TESTS=1 \
|
|
-DCCACHE_ALLOWED=FALSE \
|
|
-DNEO_DISABLE_LD_LLD=ON \
|
|
-DNEO_DISABLE_LD_GOLD=ON \
|
|
"
|
|
|
|
EXTRA_OECMAKE:append:class-target = " \
|
|
-Docloc_cmd_prefix=ocloc \
|
|
-DCMAKE_CROSSCOMPILING_EMULATOR=${WORKDIR}/qemuwrapper \
|
|
"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[levelzero] = "-DBUILD_WITH_L0=ON, -DBUILD_WITH_L0=OFF, level-zero"
|
|
|
|
do_configure:prepend:class-target () {
|
|
# Write out a qemu wrapper that will be used by cmake.
|
|
qemu_binary="${@qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST'), [d.expand('${B}/bin'),d.expand('${STAGING_DIR_HOST}${libdir}'),d.expand('${STAGING_DIR_HOST}${base_libdir}')])}"
|
|
cat > ${WORKDIR}/qemuwrapper << EOF
|
|
#!/bin/sh
|
|
$qemu_binary "\$@"
|
|
EOF
|
|
chmod +x ${WORKDIR}/qemuwrapper
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${libdir}/intel-opencl/libigdrcl.so \
|
|
${libdir}/libocloc.so \
|
|
"
|
|
|
|
FILES:${PN}-dev = "${includedir}"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
|