MIRRORS/meta-openembedded
1
0
Fork 0
mirror of https://github.com/openembedded/meta-openembedded.git synced 2025-12-16 23:36:21 +01:00
Code Issues Actions Packages Projects Releases Wiki Activity

wireguard: add WireGuard kernel module and tools

Browse Source 
WireGuard is an extremely simple yet fast and modern VPN that utilizes
state-of-the-art cryptography. It aims to be faster, simpler, leaner,
and more useful than IPSec, while avoiding the massive headache.

The recipes add the current experimental snapshot v0.0.20170421
out-of-tree kernel module and tools. The kernel module has some kernel
configuration dependencies such as some configuration part of
features/netfilter/netfilter.scc, hence netfilter.scc should be part
of KERNEL_EXTRA_FEATURES (which is the case by default).

Since wireguard-tools is TUNE_PKGARCH and depends on wireguard-module
which is MACHINE_ARCH (like all kernel modules) we need to add this
dependency to SIGGEN_EXCLUDE_SAFE_RECIPE_DEPS.

Signed-off-by: Stefan Agner <stefan@agner.ch>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
Signed-off-by: Joe MacDonald <joe_macdonald@mentor.com>
This commit is contained in:
Stefan Agner 2017-04-26 22:30:21 -07:00 committed by Joe MacDonald
parent 57d3b5c5c8
commit 9867ffa48e
4 changed files with 62 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

4
meta-networking/conf/layer.conf
View File

@ -21,3 +21,7 @@ LICENSE_PATH += "${LAYERDIR}/licenses"
# Override security flags # Override security flags
require conf/distro/include/meta_networking_security_flags.inc require conf/distro/include/meta_networking_security_flags.inc
SIGGEN_EXCLUDE_SAFE_RECIPE_DEPS += " \
wireguard-tools->wireguard-module \
"

13
meta-networking/recipes-kernel/wireguard/wireguard-module_0.0.20170421.bb Normal file
View File

@ -0,0 +1,13 @@
require wireguard.inc
inherit module
# This module requires Linux 3.10 higher and several networking related
# configuration options. For exact kernel requirements visit:
# https://www.wireguard.io/install/#kernel-requirements
EXTRA_OEMAKE += "KERNELDIR=${STAGING_KERNEL_DIR}"
MAKE_TARGETS = "module"
MODULES_INSTALL_TARGET = "module-install"
RRECOMMENDS_${PN} = "kernel-module-xt-hashlimit"

27
meta-networking/recipes-kernel/wireguard/wireguard-tools_0.0.20170421.bb Normal file
View File

@ -0,0 +1,27 @@
require wireguard.inc
inherit bash-completion systemd pkgconfig
DEPENDS = "wireguard-module libmnl"
do_compile_prepend () {
cd ${S}/tools
}
do_install () {
cd ${S}/tools
oe_runmake DESTDIR="${D}" PREFIX="${prefix}" SYSCONFDIR="${sysconfdir}" \
SYSTEMDUNITDIR="${systemd_unitdir}" \
WITH_SYSTEMDUNITS=${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'yes', '', d)} \
WITH_BASHCOMPLETION=yes \
WITH_WGQUICK=yes \
install
}
FILES_${PN} = " \
${sysconfdir} \
${systemd_unitdir} \
${bindir} \
"
RDEPENDS_${PN} = "wireguard-module"

18
meta-networking/recipes-kernel/wireguard/wireguard.inc Normal file
View File

@ -0,0 +1,18 @@
SUMMARY = "WireGuard is an extremely simple yet fast and modern VPN"
DESCRIPTION="WireGuard is a secure network tunnel, operating at layer 3, \
implemented as a kernel virtual network interface for Linux, which aims to \
replace both IPsec for most use cases, as well as popular user space and/or \
TLS-based solutions like OpenVPN, while being more secure, more performant, \
and easier to use."
SECTION = "networking"
HOMEPAGE = "https://www.wireguard.io/"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://../COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
SRC_URI = "https://git.zx2c4.com/WireGuard/snapshot/WireGuard-${PV}.tar.xz"
SRC_URI[md5sum] = "8e559f4fd672b15c38a15eb4d88cc84d"
SRC_URI[sha256sum] = "03c82af774224cd171d000ee4a519b5e474cc6842ac04967773cf77b26750000"
S = "${WORKDIR}/WireGuard-${PV}/src/"