python3-pyzmq: Upgrade 25.1.2 -> 26.3.0

* LICENSE update:
  pyzmq no longer ships an LGPL core, it is BSD-only [1].

  The LICENSE.BSD is renamed to LICENSE.md [2].

* The new version switches to scikit-build-core backend and build
  with cmake.

[1] 2f461c578b
[2] 1f4bc04f43

Signed-off-by: Mingli Yu <mingli.yu@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-python/recipes-devtools/python/python3-pyzmq/club-rpath-out.patch

@@ -1,29 +0,0 @@
-From efae4e08d13e0958d929ea524e21c0a210b31982 Mon Sep 17 00:00:00 2001
-From: Leon Anavi <leon.anavi@konsulko.com>
-Date: Fri, 22 Jan 2021 11:41:12 +0200
-Subject: [PATCH] setup.py: Adjust _add_rpath
-
-Fix error: unrecognized command-line option '-R'
-
-Upstream-Status: Inappropriate [oe specific]
-
-Signed-off-by: Leon Anavi <leon.anavi@konsulko.com>
-
----
- setup.py | 3 ---
- 1 file changed, 3 deletions(-)
-
-diff --git a/setup.py b/setup.py
-index b634d94..7f6a2f1 100755
---- a/setup.py
-+++ b/setup.py
-@@ -235,9 +235,6 @@ def _add_rpath(settings, path):
-     """
-     if sys.platform == 'darwin':
-         settings['extra_link_args'].extend(['-Wl,-rpath', '-Wl,%s' % path])
--    else:
--        settings['runtime_library_dirs'].append(path)
--
- 
- def settings_from_prefix(prefix=None):
-     """load appropriate library/include settings from ZMQ prefix"""

meta-python/recipes-devtools/python/python3-pyzmq_25.1.2.bb

@@ -1,58 +0,0 @@
-SUMMARY = "PyZMQ: Python bindings for ZMQ"
-DESCRIPTION = "This package contains Python bindings for ZeroMQ. ZMQ is a lightweight and fast messaging implementation."
-HOMEPAGE = "https://zeromq.org/bindings:python"
-LICENSE = "BSD-3-Clause & LGPL-3.0-only"
-LIC_FILES_CHKSUM = "\
-    file://LICENSE.BSD;md5=1787206f198344195a671b60326c59dc \
-    file://LICENSE.LESSER;md5=0e99bfbdd8b9d33b0221986fe3be89ed \
-"
-
-DEPENDS = "python3-packaging-native python3-setuptools-scm-native zeromq"
-
-SRC_URI:append = " \
-    file://club-rpath-out.patch \
-    file://run-ptest \
-"
-SRC_URI[sha256sum] = "93f1aa311e8bb912e34f004cf186407a4e90eec4f0ecc0efd26056bf7eda0226"
-
-inherit pypi pkgconfig python_setuptools_build_meta ptest cython
-
-PACKAGES =+ "\
-    ${PN}-test \
-"
-
-FILES:${PN}-test += "\
-    ${PYTHON_SITEPACKAGES_DIR}/*/tests \
-"
-
-RDEPENDS:${PN} += "\
-        python3-json \
-        python3-multiprocessing \
-        python3-tornado \
-"
-
-RDEPENDS:${PN}-ptest += "\
-    ${PN}-test \
-    python3-pytest \
-    python3-unittest-automake-output \
-    python3-unixadmin \
-"
-
-do_compile:prepend() {
-    echo [global] > ${S}/setup.cfg
-    echo zmq_prefix = ${STAGING_DIR_HOST} >> ${S}/setup.cfg
-    echo have_sys_un_h = True >> ${S}/setup.cfg
-    echo skip_check_zmq = True >> ${S}/setup.cfg
-    echo libzmq_extension = False >> ${S}/setup.cfg
-    echo no_libzmq_extension = True >> ${S}/setup.cfg
-}
-
-do_install:append() {
-        sed -i -e 's#${RECIPE_SYSROOT}##g' ${D}${PYTHON_SITEPACKAGES_DIR}/zmq/utils/config.json
-        sed -i -e 's#${RECIPE_SYSROOT}##g' ${D}${PYTHON_SITEPACKAGES_DIR}/zmq/utils/compiler.json
-}
-
-do_install_ptest() {
-        install -d ${D}${PTEST_PATH}/tests
-        cp -rf ${S}/zmq/tests/* ${D}${PTEST_PATH}/tests/
-}

meta-python/recipes-devtools/python/python3-pyzmq_26.3.0.bb

@@ -0,0 +1,60 @@
+SUMMARY = "PyZMQ: Python bindings for ZMQ"
+DESCRIPTION = "This package contains Python bindings for ZeroMQ. ZMQ is a lightweight and fast messaging implementation."
+HOMEPAGE = "https://zeromq.org/bindings:python"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "\
+    file://LICENSE.md;md5=1787206f198344195a671b60326c59dc \
+"
+
+DEPENDS = "python3-packaging-native \
+           python3-setuptools-scm-native \
+           python3-scikit-build-core-native \
+           cmake-native \
+           ninja-native \
+           zeromq \
+"
+
+PEP517_BUILD_OPTS = "--skip-dependency-check \
+                     -Ccmake.define.PYZMQ_LIBZMQ_RPATH=OFF \
+                     -Ccmake.define.PYZMQ_NO_BUNDLE=ON \
+                     -Ccmake.define.CMAKE_FIND_ROOT_PATH_MODE_PACKAGE=ONLY \
+                     -Ccmake.define.CMAKE_FIND_ROOT_PATH_MODE_PROGRAM=ONLY \
+                     -Ccmake.define.CMAKE_FIND_ROOT_PATH_MODE_LIBRARY=ONLY \
+                     -Ccmake.define.CMAKE_FIND_ROOT_PATH_MODE_INCLUDE=ONLY \
+                     -Ccmake.define.CMAKE_FIND_ROOT_PATH="${STAGING_DIR_NATIVE}" \
+                     -Ccmake.build-type="RelWithDebInfo" \
+"
+
+SRC_URI:append = " \
+    file://run-ptest \
+"
+
+SRC_URI[sha256sum] = "f1cd68b8236faab78138a8fc703f7ca0ad431b17a3fcac696358600d4e6243b3"
+
+inherit pypi pkgconfig python_setuptools_build_meta ptest cython
+
+PACKAGES =+ "\
+    ${PN}-test \
+"
+
+FILES:${PN}-test += "\
+    ${PYTHON_SITEPACKAGES_DIR}/*/tests \
+"
+
+RDEPENDS:${PN} += "\
+        python3-json \
+        python3-multiprocessing \
+        python3-tornado \
+"
+
+RDEPENDS:${PN}-ptest += "\
+    ${PN}-test \
+    python3-pytest \
+    python3-unittest-automake-output \
+    python3-unixadmin \
+"
+
+do_install_ptest() {
+        install -d ${D}${PTEST_PATH}/tests
+        cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}