mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-12-14 14:25:53 +01:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
38 lines
1.1 KiB
BlitzBasic
38 lines
1.1 KiB
BlitzBasic
SUMMARY = "RenderDoc recipe providing renderdoccmd"
|
|
DESCRIPTION = "RenderDoc is a frame-capture based graphics debugger"
|
|
HOMEPAGE = "https://github.com/baldurk/renderdoc"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.md;md5=963d134bd809d24547253120513346d3"
|
|
|
|
SRCREV = "34c3c40787f440da9c2947cd63a41e6c4d1f95b9"
|
|
SRC_URI = " \
|
|
git://github.com/baldurk/${BPN}.git;protocol=https;branch=v1.x \
|
|
"
|
|
|
|
DEPENDS += "virtual/libx11 virtual/libgl libxcb xcb-util-keysyms"
|
|
|
|
RDEPENDS:${PN} = "libxcb xcb-util-keysyms"
|
|
|
|
inherit cmake pkgconfig python3native features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "x11 opengl"
|
|
|
|
python __anonymous () {
|
|
# only works on glibc systems
|
|
if d.getVar('TCLIBC') != "glibc":
|
|
raise bb.parse.SkipRecipe("incompatible with %s C library" % d.getVar('TCLIBC'))
|
|
}
|
|
|
|
COMPATIBLE_HOST = "(x86_64|i.86|arm|aarch64).*-linux"
|
|
|
|
EXTRA_OECMAKE += "\
|
|
-DENABLE_QRENDERDOC=OFF \
|
|
-DENABLE_PYRENDERDOC=OFF \
|
|
-DENABLE_RENDERDOCCMD=ON \
|
|
-DCMAKE_BUILD_TYPE=Release \
|
|
-DHOST_NATIVE_CPP_COMPILER="${BUILD_CXX}" \
|
|
"
|
|
|
|
FILES:${PN} += "${libdir}"
|
|
FILES:${PN}-dev = "${includedir}"
|