mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-12-14 14:25:53 +01:00
e29afd0c0c
Changelog: =========== -Permit percentages to have comma's in icesh. -Keep accurate track of window changes in workspace buttons for PagerShowPreview. Only redraw affected workspace buttons, which reduces the total number of workspace button redraws, especially for larges number of workspace buttons. -Add key bindings for single window tiling operations for issues bbidulock/icewm#335, ice-wm/icewm#74 and ice-wm/icewm#84. -Complete -e option. -WindowMaker dock apps are supported. -Support more HTML entities in icehelp. -Remove dependency on asciidoc and prefer markdown format for the manual. -Prevent warnings. -Also install markdown. -Try srcdir. -Cleanup test and prefer markdown manual. -Cleanup key grabs. -Drop obsolete wmOccupyAll(). -Accept either markdown or asciidoc to generate manual html with CMake. -Add markdown and icesh. -Automatically detect and prevent race conditions in icesh relating to moving and sizing windows for issue #335. Improve the accuracy of the "sizeto" command in icesh for issue #335. Add "extents" command to icesh. Add "workarea" command to icesh. -Get rid of the frameContext. -Prefer findClient in two cases: unmap notify and recv ping. -Merge remote-tracking branch 'upstream/icewm-1-4-BRANCH' into icewm-1-4-BRANCH -Merge branch 'icewm-1-4-BRANCH' Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
47 lines
1.7 KiB
BlitzBasic
47 lines
1.7 KiB
BlitzBasic
DESCRIPTION = "Ice Window Manager (IceWM)"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=4a26952467ef79a7efca4a9cf52d417b"
|
|
|
|
SRC_URI = "https://github.com/ice-wm/${BPN}/releases/download/${PV}/${BPN}-${PV}.tar.lz \
|
|
file://0001-configure.ac-skip-running-test-program-when-cross-co.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "af7bab3472189febf50753eaecfac586901419d282cbcbff92e860d4b74894b3"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/ice-wm/${BPN}/releases"
|
|
|
|
inherit autotools pkgconfig gettext perlnative features_check qemu update-alternatives
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
EXTRA_OECONF += "--with-libdir=${datadir}/icewm \
|
|
--with-cfgdir=${sysconfdir}/icewm \
|
|
--with-docdir=${docdir}/icewm \
|
|
--enable-fribidi \
|
|
--enable-xinerama \
|
|
--enable-shape"
|
|
|
|
DEPENDS = "asciidoc-native fontconfig fribidi gdk-pixbuf imlib2 libxft libxpm libxrandr \
|
|
libxinerama libice libsm libx11 libxext libxrender libxcomposite libxdamage \
|
|
libxfixes"
|
|
DEPENDS:append = " qemu-native"
|
|
RDEPENDS:${PN} = "perl fribidi imlib2 imlib2-loaders"
|
|
|
|
do_compile:prepend:class-target() {
|
|
|
|
cd ${B}
|
|
oe_runmake -C src genpref
|
|
|
|
qemu_binary="${@qemu_wrapper_cmdline(d, '${STAGING_DIR_TARGET}',['${B}/src/.libs','${STAGING_DIR_TARGET}/${libdir}','${STAGING_DIR_TARGET}/${base_libdir}'])}"
|
|
cat >qemuwrapper <<EOF
|
|
#!/bin/sh
|
|
${qemu_binary} src/genpref "\$@"
|
|
EOF
|
|
chmod +x qemuwrapper
|
|
./qemuwrapper > src/preferences
|
|
}
|
|
|
|
ALTERNATIVE:${PN} = "x-session-manager"
|
|
ALTERNATIVE_TARGET[x-session-manager] = "${bindir}/icewm-session"
|
|
ALTERNATIVE_PRIORITY_${PN} = "100"
|
|
|
|
FILES:${PN} += "${datadir}/xsessions"
|