meta-openembedded/meta-python/recipes-devtools/python/python3-h5py_3.12.1.bb
Wang Mingyu 34821f5c4b
python3-h5py: upgrade 3.11.0 -> 3.12.1
0001-setup_build.py-avoid-absolute-path.patch
refreshed for 3.12.1

Changelog:
 https://github.com/h5py/h5py/blob/master/docs/whatsnew/3.12.rst

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
2024-09-30 07:34:25 -07:00

40 lines
1.1 KiB
BlitzBasic

SUMMARY = "Provides both a high- and low-level interface to the HDF5 library from Python."
HOMEPAGE = "https://www.h5py.org/"
SECTION = "devel/python"
LICENSE = "BSD-3-Clause"
LIC_FILES_CHKSUM = "file://LICENSE;md5=113251d71fb0384712c719b567261c5c"
SRC_URI[sha256sum] = "326d70b53d31baa61f00b8aa5f95c2fcb9621a3ee8365d770c551a13dbbcbfdf"
SRC_URI += "file://0001-setup_build.py-avoid-absolute-path.patch"
inherit pkgconfig pypi setuptools3
BBCLASSEXTEND = "native"
DEPENDS = "python3-pkgconfig-native \
python3-cython-native \
python3-numpy-native \
python3-six-native \
hdf5-native \
python3 \
hdf5 \
"
PACKAGESPLITFUNCS =+ "fix_cythonized_sources"
fix_cythonized_sources() {
for f in `grep -l -r -e '\/* Generated by Cython.*/$' ${PKGD}${TARGET_DBGSRC_DIR}`; do
if [ -e $f ]; then
sed -i -e 's#${RECIPE_SYSROOT_NATIVE}##g' $f
fi
done
}
RDEPENDS:${PN} = "python3-numpy \
python3-six \
python3-json \
"
export HDF5_VERSION="1.14.0"