meta-openembedded/meta-webserver/recipes-php/phpmyadmin/phpmyadmin_5.2.1.bb
Khem Raj ffc64e9c6f
recipes: Start WORKDIR -> UNPACKDIR transition
Replace references of WORKDIR with UNPACKDIR where it makes sense to do
so in preparation for changing the default value of UNPACKDIR.

Signed-off-by: Khem Raj <raj.khem@gmail.com>
2024-05-23 08:44:44 -07:00

41 lines
1.5 KiB
BlitzBasic

SUMMARY = "Web-based MySQL administration interface"
HOMEPAGE = "http://www.phpmyadmin.net"
# Main code is GPLv2, vendor/tecnickcom/tcpdf is under LGPLv3, js/jquery is under MIT
LICENSE = "GPL-2.0-only & LGPL-3.0-only & MIT"
LIC_FILES_CHKSUM = "file://LICENSE;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
file://vendor/tecnickcom/tcpdf/LICENSE.TXT;md5=d0ff7e060074497f34481cf574e8a581 \
file://js/vendor/jquery/MIT-LICENSE.txt;md5=de877aa6d744cc160ff41c26a8e4811f \
"
SRC_URI = "https://files.phpmyadmin.net/phpMyAdmin/${PV}/phpMyAdmin-${PV}-all-languages.tar.xz \
file://apache.conf \
"
SRC_URI[sha256sum] = "373f9599dfbd96d6fe75316d5dad189e68c305f297edf42377db9dd6b41b2557"
UPSTREAM_CHECK_URI = "https://www.phpmyadmin.net/downloads/"
UPSTREAM_CHECK_REGEX = "phpMyAdmin-(?P<pver>\d+(\.\d+)+)-all-languages.tar.xz"
S = "${WORKDIR}/phpMyAdmin-${PV}-all-languages"
inherit allarch
do_install() {
install -d ${D}${datadir}/${BPN}
cp -R --no-dereference --preserve=mode,links -v * ${D}${datadir}/${BPN}
chown -R root:root ${D}${datadir}/${BPN}
# Don't install patches to target
rm -rf ${D}${datadir}/${BPN}/patches
install -d ${D}${sysconfdir}/apache2/conf.d
install -m 0644 ${UNPACKDIR}/apache.conf ${D}${sysconfdir}/apache2/conf.d/phpmyadmin.conf
# Remove a few scripts that explicitly require bash (!)
rm -f ${D}${datadir}/phpmyadmin/libraries/transformations/*.sh
}
FILES:${PN} = "${datadir}/${BPN} \
${sysconfdir}/apache2/conf.d"
RDEPENDS:${PN} += "bash php-cli"