mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-12-15 06:45:32 +01:00
a992e7d222
Changelog: - make request and reconfigure behavior for lines requested by names consistent with that of lines requested by offsets - fix parsing non-tuple keys when requesting a line - disable UP045 linter check - use quoted types when casting - generate wheels for CPython 3.14 - issue a warning when reconfiguring a line not in the original request - update dependencies for wheel generation - update licensing information - coding style fixes - minor performance improvements License-Update: Follow the PEP 639 specification and remove the deprecated license classifier in pyproject.toml. Make the license key a top-level string. No changes in the license type. Signed-off-by: Bartosz Golaszewski <bartosz.golaszewski@linaro.org> Signed-off-by: Khem Raj <raj.khem@gmail.com>
46 lines
1.4 KiB
BlitzBasic
46 lines
1.4 KiB
BlitzBasic
SUMMARY = "Python bindings for libgpiod."
|
|
|
|
LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later & CC-BY-SA-4.0"
|
|
# The actual license files live in the upstream libgpiod from which the pypi
|
|
# package is spun out.
|
|
LIC_FILES_CHKSUM = "file://pyproject.toml;beginline=13;endline=13;md5=0fbc720d3e48432ee239eedb6adb0f07"
|
|
|
|
SRC_URI += "file://run-ptest"
|
|
|
|
SRC_URI[sha256sum] = "9243a1a59d084ec749d1df4a1e2f238ffb9d94515b0d9f5335460175143c3aa1"
|
|
|
|
inherit python_setuptools_build_meta python_pep517 ptest pypi
|
|
|
|
DEPENDS += " \
|
|
libgpiod \
|
|
python3-setuptools-native \
|
|
"
|
|
RDEPENDS:${PN} += " \
|
|
libgpiod (>= 2.1) \
|
|
python3-datetime \
|
|
python3-profile \
|
|
"
|
|
RDEPENDS:${PN}-ptest += " \
|
|
libgpiod-gpiosim \
|
|
python3-setuptools \
|
|
"
|
|
|
|
export LINK_SYSTEM_LIBGPIOD = "1"
|
|
|
|
do_compile_ptest() {
|
|
setup_target_config
|
|
nativepython3 build_tests.py
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/gpiod-test/gpiosim
|
|
install -d ${D}${PTEST_PATH}/gpiod-test/system
|
|
install -m 0644 ${S}/tests/*.py ${D}${PTEST_PATH}/gpiod-test/
|
|
install -m 0644 ${B}/tests/gpiosim/_ext* ${D}${PTEST_PATH}/gpiod-test/gpiosim
|
|
install -m 0644 ${S}/tests/gpiosim/*.py ${D}${PTEST_PATH}/gpiod-test/gpiosim
|
|
install -m 0644 ${B}/tests/system/_ext* ${D}${PTEST_PATH}/gpiod-test/system
|
|
install -m 0644 ${S}/tests/system/*.py ${D}${PTEST_PATH}/gpiod-test/system
|
|
}
|
|
|
|
INSANE_SKIP:${PN}-ptest += "buildpaths"
|