mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-07-19 15:29:08 +02:00
9513a6a51a
This is minor release that contains some fixes and code improvements. There are no new interfaces but line.Value can now correctly be cast to bool and __repr__() implementations have been fixed to actually allow using them to recreate objects. Starting from this release pypi also provides wheels but this isn't relevant to meta-oe. Signed-off-by: Bartosz Golaszewski <bartosz.golaszewski@linaro.org> Signed-off-by: Khem Raj <raj.khem@gmail.com>
47 lines
1.4 KiB
BlitzBasic
47 lines
1.4 KiB
BlitzBasic
SUMMARY = "Python bindings for libgpiod."
|
|
|
|
LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later & CC-BY-SA-4.0"
|
|
# The actual license files live in the upstream libgpiod from which the pypi
|
|
# package is spun out.
|
|
LIC_FILES_CHKSUM = "file://setup.py;beginline=237;endline=237;md5=f5ddb56912b7f20bf94aa4d1bdcd3533"
|
|
|
|
SRC_URI += "file://run-ptest"
|
|
|
|
SRC_URI[sha256sum] = "4447f05ab42a9ea596e548a9a65389aa84bf61c95dc7a78074bb9c5f8f6a6b35"
|
|
|
|
inherit setuptools3-base python_pep517 ptest pypi
|
|
|
|
DEPENDS += " \
|
|
libgpiod \
|
|
python3-setuptools-native \
|
|
"
|
|
RDEPENDS:${PN} += " \
|
|
libgpiod (>= 2.1) \
|
|
python3-datetime \
|
|
python3-profile \
|
|
"
|
|
RDEPENDS:${PN}-ptest += " \
|
|
libgpiod-ptest \
|
|
python3-setuptools \
|
|
"
|
|
RRECOMMENDS:${PN}-ptest += "kernel-module-configfs"
|
|
|
|
export LINK_SYSTEM_LIBGPIOD = "1"
|
|
|
|
do_compile_ptest() {
|
|
setup_target_config
|
|
nativepython3 build_tests.py
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/gpiod-test/gpiosim
|
|
install -d ${D}${PTEST_PATH}/gpiod-test/procname
|
|
install -m 0644 ${S}/tests/*.py ${D}${PTEST_PATH}/gpiod-test/
|
|
install -m 0644 ${B}/tests/gpiosim/_ext* ${D}${PTEST_PATH}/gpiod-test/gpiosim
|
|
install -m 0644 ${S}/tests/gpiosim/*.py ${D}${PTEST_PATH}/gpiod-test/gpiosim
|
|
install -m 0644 ${B}/tests/procname/_ext* ${D}${PTEST_PATH}/gpiod-test/procname
|
|
install -m 0644 ${S}/tests/procname/*.py ${D}${PTEST_PATH}/gpiod-test/procname
|
|
}
|
|
|
|
INSANE_SKIP:${PN}-ptest += "buildpaths"
|