mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-07-19 15:29:08 +02:00
f0c767407d
work arounds for: meta-oe/meta-oe/recipes-devtools/nodejs/nodejs_20.12.2.bb:do_compile meta-oe/meta-oe/recipes-support/pidgin/pidgin_2.14.2.bb:do_compile meta-oe/meta-oe/recipes-devtools/uw-imap/uw-imap_2007f.bb:do_compile meta-oe/meta-oe/recipes-extended/rrdtool/rrdtool_1.8.0.bb:do_compile meta-oe/meta-oe/recipes-extended/cmpi-bindings/cmpi-bindings_1.0.4.bb:do_compile meta-oe/meta-python/recipes-devtools/python/python3-gevent_24.2.1.bb:do_compile meta-oe/meta-oe/recipes-support/avro/avro-c++_1.11.3.bb:do_compile meta-oe/meta-python/recipes-devtools/python/python3-h5py_3.10.0.bb:do_compile meta-oe/meta-oe/recipes-multimedia/cdrkit/cdrkit_1.1.11.bb:do_compile meta-oe/meta-networking/recipes-connectivity/openthread/ot-br-posix_git.bb:do_compile meta-oe/meta-oe/recipes-devtools/heaptrack/heaptrack_1.2.0.bb:do_configure meta-oe/meta-oe/recipes-support/avro/avro-c_1.11.3.bb:do_compile meta-oe/meta-oe/recipes-core/usleep/usleep_1.2.bb:do_compile meta-oe/meta-networking/recipes-protocols/openflow/openflow_git.bb:do_compile meta-oe/meta-oe/recipes-extended/sblim-sfcc/sblim-sfcc_2.2.8.bb:do_compile meta-oe/meta-networking/recipes-support/linux-atm/linux-atm_2.5.2.bb:do_compile meta-oe/meta-oe/recipes-kernel/ipmitool/ipmitool_1.8.19.bb:do_compile meta-oe/meta-networking/recipes-support/ssmping/ssmping_0.9.1.bb:do_compile meta-oe/meta-oe/recipes-connectivity/wifi-test-suite/wifi-test-suite_10.10.1.bb:do_compile meta-oe/meta-oe/recipes-extended/zsync/zsync-curl_git.bb:do_compile meta-oe/meta-python/recipes-devtools/python/python3-kivy_2.3.0.bb:do_compile meta-oe/meta-oe/recipes-support/openct/openct_0.6.20.bb:do_compile meta-oe/meta-oe/recipes-benchmark/dhrystone/dhrystone_2.1.bb:do_compile meta-oe/meta-networking/recipes-daemons/ncftp/ncftp_3.2.7.bb:do_compile meta-oe/meta-oe/recipes-support/daemontools/daemontools_0.76.bb:do_compile meta-oe/meta-oe/recipes-devtools/libgee/libgee_0.20.6.bb:do_compile meta-oe/meta-oe/recipes-devtools/mcpp/mcpp_2.7.2.bb:do_compile meta-oe/meta-oe/recipes-devtools/android-tools/android-tools_5.1.1.r37.bb:do_compile meta-oe/meta-networking/recipes-connectivity/dibbler/dibbler_git.bb:do_compile meta-oe/meta-oe/recipes-devtools/glade/glade_3.22.2.bb:do_compile http://errors.yoctoproject.org/Errors/Build/183124/ Signed-off-by: Martin Jansa <martin.jansa@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
75 lines
3.1 KiB
BlitzBasic
75 lines
3.1 KiB
BlitzBasic
SUMMARY = "OpenFlow communications protocol"
|
|
DESCRIPTION = "\
|
|
Open standard that enables researchers to run experimental protocols in \
|
|
contained networks. OpenFlow is a communications interface between \
|
|
control and forwarding planes of a software-defined networking architecture.\
|
|
"
|
|
HOMEPAGE = "http://www.openflow.org"
|
|
|
|
SECTION = "net"
|
|
LICENSE = "GPL-2.0-only"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=e870c934e2c3d6ccf085fd7cf0a1e2e2"
|
|
|
|
SRCREV = "82ad07d997b0b2ee70e1b2c7e82fcc6d0ccf23ea"
|
|
|
|
PV = "1.0+git"
|
|
|
|
SRC_URI = "git://github.com/mininet/openflow;protocol=https;branch=master \
|
|
file://0001-Check-and-use-strlcpy-from-libc-before-defining-own.patch \
|
|
file://0002-lib-netdev-Adjust-header-include-sequence.patch \
|
|
file://0001-generate-not-static-get_dh-functions.patch \
|
|
file://0001-socket-util-Include-sys-stat.h-for-fchmod.patch \
|
|
file://0001-Makefile.am-Specify-export-dynamic-directly-to-linke.patch \
|
|
file://0001-Link-in-libexecinfo-if-it-has-backtrace-API.patch \
|
|
"
|
|
CVE_STATUS[CVE-2015-1611] = "not-applicable-config: Not referred to our implementation of openflow"
|
|
CVE_STATUS[CVE-2015-1612] = "not-applicable-config: Not referred to our implementation of openflow"
|
|
CVE_STATUS[CVE-2018-1078] = "cpe-incorrect: This CVE is not for this product but cve-check assumes it is \
|
|
because two CPE collides when checking the NVD database"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[openssl] = "--enable-ssl,--disable-ssl, openssl openssl-native, libssl"
|
|
|
|
EXTRA_OECONF += " \
|
|
KARCH=${TARGET_ARCH} \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'openssl', 'SSL_LIBS="-lssl -lcrypto"', '', d)} \
|
|
"
|
|
DEPENDS:append:libc-musl = " libexecinfo"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep pkgconfig
|
|
|
|
do_configure:prepend() {
|
|
./boot.sh
|
|
}
|
|
|
|
do_install:append() {
|
|
# Remove /var/run as it is created on startup
|
|
rm -rf ${D}${localstatedir}/run
|
|
|
|
# /var/log/openflow needs to be created in runtime. Use rmdir to catch if
|
|
# upstream stops creating /var/log/openflow, or adds something else in
|
|
# /var/log.
|
|
rmdir ${D}${localstatedir}/log/${BPN} ${D}${localstatedir}/log
|
|
rmdir --ignore-fail-on-non-empty ${D}${localstatedir}
|
|
|
|
# Create /var/log/openflow in runtime.
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}" ]; then
|
|
install -d ${D}${nonarch_libdir}/tmpfiles.d
|
|
echo "d ${localstatedir}/log/${BPN} - - - -" > ${D}${nonarch_libdir}/tmpfiles.d/${BPN}.conf
|
|
fi
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'sysvinit', d)}" ]; then
|
|
install -d ${D}${sysconfdir}/default/volatiles
|
|
echo "d root root 0755 ${localstatedir}/log/${BPN} none" > ${D}${sysconfdir}/default/volatiles/99_${BPN}
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += "${nonarch_libdir}/tmpfiles.d"
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/766898/
|
|
# lib/flow.c:213:48: error: initialization of 'const struct arp_eth_header *' from incompatible pointer type 'struct arp_header *' [-Wincompatible-pointer-types]
|
|
# lib/backtrace.c:126:32: error: passing argument 1 of 'backtrace' from incompatible pointer type [-Wincompatible-pointer-types]
|
|
CFLAGS += "-Wno-error=incompatible-pointer-types"
|