mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-07-19 15:29:08 +02:00
be59cf4cb5
0001-testtyp.c-Use-proper-prototype-for-main-function.patch refreshed for 1.45 Changelog: ============ - Correct wide character data types to fix compile failure. - Implement A_ITALIC - Fix missing file introduced in 1.42 that prevents all builds from working. - Add missing return type declarations so it works with modern C compilers. - Rename test.syms program to testsyms, because it is a more conventional name format. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
32 lines
1.2 KiB
BlitzBasic
32 lines
1.2 KiB
BlitzBasic
DESCRIPTION = "lib-curses provides an interface between Perl programs and \
|
|
the curses library."
|
|
|
|
SECTION = "libs"
|
|
LICENSE = "Artistic-1.0 | GPL-1.0-or-later"
|
|
|
|
LIC_FILES_CHKSUM = "file://README;beginline=26;endline=30;md5=0b37356c5e9e28080a3422d82af8af09"
|
|
|
|
DEPENDS += "perl ncurses "
|
|
|
|
SRC_URI = "http://www.cpan.org/authors/id/G/GI/GIRAFFED/Curses-${PV}.tar.gz \
|
|
file://0001-testtyp.c-Use-proper-prototype-for-main-function.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "84221e0013a2d64a0bae6a32bb44b1ae5734d2cb0465fb89af3e3abd6e05aeb2"
|
|
|
|
S = "${WORKDIR}/Curses-${PV}"
|
|
|
|
EXTRA_CPANFLAGS = "INC=-I${STAGING_INCDIR} LIBS=-L${STAGING_LIBDIR} TEST_SYMS_OPTS=-v"
|
|
|
|
# enable NCURSES_WIDECHAR=1 only if ENABLE_WIDEC has not been explicitly disabled (e.g. by the distro config).
|
|
# When compiling against the ncurses library, NCURSES_WIDECHAR needs to explicitly set to 0 in this case.
|
|
CFLAGS:append:libc-musl = "${@' -DNCURSES_WIDECHAR=1' if bb.utils.to_boolean((d.getVar('ENABLE_WIDEC') or 'True')) else ' -DNCURSES_WIDECHAR=0'} -DNCURSES_INTERNALS"
|
|
|
|
inherit cpan
|
|
|
|
do_compile() {
|
|
export LIBC="$(find ${STAGING_DIR_TARGET}/${base_libdir}/ -name 'libc-*.so')"
|
|
cpan_do_compile
|
|
}
|
|
|