mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-12-14 14:25:53 +01:00
c436334d88
It is necessary to set the revision number to prevent it from being fetched from the remote. The revision number has been configured relative to release 2.10.0. Signed-off-by: Sebastien LEFEVRE <sebastien.lefevre@smile.fr> Signed-off-by: Khem Raj <raj.khem@gmail.com>
35 lines
1.3 KiB
BlitzBasic
35 lines
1.3 KiB
BlitzBasic
SUMMARY = "library that provides operations for data in the UTF-8 encoding"
|
|
DESCRIPTION = "utf8proc is a small, clean C library that provides Unicode \
|
|
normalization, case-folding, and other operations for data in the UTF-8 \
|
|
encoding, supporting Unicode version 16.0"
|
|
HOMEPAGE = "https://juliastrings.github.io/utf8proc/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "MIT & Unicode-3.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.md;md5=96d5a3ba306e0f24fb289427af484408"
|
|
|
|
SRC_URI = "\
|
|
git://github.com/JuliaStrings/utf8proc;protocol=https;branch=master;tag=v${PV} \
|
|
file://run-ptest \
|
|
"
|
|
SRCREV = "a1b99daa2a3393884220264c927a48ba1251a9c6"
|
|
|
|
inherit cmake ptest
|
|
|
|
EXTRA_OECMAKE = "\
|
|
-DBUILD_SHARED_LIBS=ON \
|
|
${@bb.utils.contains('PTEST_ENABLED', '1', '-DBUILD_TESTING=ON -DUTF8PROC_ENABLE_TESTING=ON ', '', d)} \
|
|
"
|
|
|
|
do_install_ptest() {
|
|
# this list and run-ptest needs to be updated on upgrade (the project uses add_test feature)
|
|
for t in "case" custom iterate misc printproperty valid charwidth graphemetest normtest; do
|
|
install -m 0755 ${B}/$t ${D}${PTEST_PATH}/
|
|
done
|
|
install -d ${D}${PTEST_PATH}/data
|
|
install -m 0644 ${B}/data/GraphemeBreakTest.txt ${D}${PTEST_PATH}/data/
|
|
install -m 0644 ${B}/data/NormalizationTest.txt ${D}${PTEST_PATH}/data/
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|