meta-openembedded/meta-python/recipes-devtools/python/python3-pyserial_3.5.bb
Martin Jansa c61dc077bb Convert to new override syntax
This is the result of automated script (0.9.1) conversion:

oe-core/scripts/contrib/convert-overrides.py .

converting the metadata to use ":" as the override character instead of "_".

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
2021-08-03 10:21:25 -07:00

63 lines
1.7 KiB
BlitzBasic

SUMMARY = "Serial Port Support for Python"
LICENSE = "BSD-3-Clause"
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=520e45e59fc2cf94aa53850f46b86436"
SRC_URI[sha256sum] = "3c77e014170dfffbd816e6ffc205e9842efb10be9f58ec16d3e8675b4925cddb"
inherit pypi setuptools3 ptest
do_install:append() {
rm -f ${D}${bindir}/pyserial-miniterm
rm -f ${D}${bindir}/pyserial-ports
rmdir ${D}${bindir}
}
PACKAGES =+ "${PN}-java ${PN}-osx ${PN}-win32 ${PN}-tools"
FILES:${PN}-java = " \
${PYTHON_SITEPACKAGES_DIR}/serial/*java* \
${PYTHON_SITEPACKAGES_DIR}/serial/__pycache__/*java* \
"
FILES:${PN}-osx = " \
${PYTHON_SITEPACKAGES_DIR}/serial/tools/*osx* \
${PYTHON_SITEPACKAGES_DIR}/serial/tools/__pycache__/*osx* \
"
FILES:${PN}-win32 = " \
${PYTHON_SITEPACKAGES_DIR}/serial/*serialcli* \
${PYTHON_SITEPACKAGES_DIR}/serial/__pycache__/*serialcli* \
${PYTHON_SITEPACKAGES_DIR}/serial/*win32* \
${PYTHON_SITEPACKAGES_DIR}/serial/__pycache__/*win32* \
${PYTHON_SITEPACKAGES_DIR}/serial/tools/miniterm* \
${PYTHON_SITEPACKAGES_DIR}/serial/tools/__pycache__/miniterm* \
${PYTHON_SITEPACKAGES_DIR}/serial/tools/*windows* \
${PYTHON_SITEPACKAGES_DIR}/serial/tools/__pycache__/*windows* \
"
RDEPENDS:${PN} = "\
${PYTHON_PN}-fcntl \
${PYTHON_PN}-io \
${PYTHON_PN}-logging \
${PYTHON_PN}-netclient \
${PYTHON_PN}-numbers \
${PYTHON_PN}-shell \
${PYTHON_PN}-stringold \
${PYTHON_PN}-threading \
"
BBCLASSEXTEND = "native nativesdk"
SRC_URI += " \
file://run-ptest \
"
RDEPENDS:${PN}-ptest += " \
${PYTHON_PN}-pytest \
"
do_install_ptest() {
install -d ${D}${PTEST_PATH}/test
cp -rf ${S}/test/* ${D}${PTEST_PATH}/test/
}