meta-openembedded/meta-python/recipes-devtools/python/python3-pydantic-core_2.33.1.bb
Khem Raj 6a3128f17b
pydantic: Mark host incompatible on RISCV32
pydantic-core needs to be ported to work on rv32

Signed-off-by: Khem Raj <raj.khem@gmail.com>
2025-04-06 18:46:25 -07:00

52 lines
1.6 KiB
BlitzBasic

SUMMARY = "Provides the core functionality for pydantic validation and serialization."
DESCRIPTION = "This package provides the core functionality for \
pydantic validation and serialization.\
\
Pydantic-core is currently around 17x faster than pydantic V1."
HOMEPAGE = "https://github.com/pydantic/pydantic-core"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://LICENSE;md5=ab599c188b4a314d2856b3a55030c75c"
require ${BPN}-crates.inc
SRC_URI[sha256sum] = "bcc9c6fdb0ced789245b02b7d6603e17d1563064ddcfc36f046b61c0c05dd9df"
DEPENDS = "python3-maturin-native python3-typing-extensions"
inherit pypi cargo-update-recipe-crates python_maturin ptest-python-pytest
PYPI_PACKAGE = "pydantic_core"
UPSTREAM_CHECK_PYPI_PACKAGE = "${PYPI_PACKAGE}"
RDEPENDS:${PN} += " \
python3-compression \
python3-typing-extensions \
"
INSANE_SKIP:${PN} = "already-stripped"
# python3-misc is for Lib/timeit.py which is not split out elsewhere
RDEPENDS:${PN}-ptest += "\
python3-dateutil \
python3-dirty-equals \
python3-hypothesis \
python3-inline-snapshot \
python3-misc \
python3-pytest-mock \
python3-pytest-timeout \
python3-pytest-benchmark \
python3-tzdata \
python3-zoneinfo \
"
do_install_ptest:append () {
cp -rf ${S}/tests/ ${D}${PTEST_PATH}/
sed -i -e "/--automake/ s/$/ -k 'not test_model_class_root_validator_wrap and not test_model_class_root_validator_before and not test_model_class_root_validator_after'/" ${D}${PTEST_PATH}/run-ptest
}
BBCLASSEXTEND = "native nativesdk"
# It needs bitvec to adopt radum 1.x see https://github.com/ferrilab/bitvec/pull/220
COMPATIBLE_HOST:riscv32 = "null"