meta-openembedded/meta-python/recipes-devtools/python/python3-grpcio_1.43.0.bb
Xu Huan 490bd9ec5e python3-grpcio: upgrade 1.41.1 -> 1.43.0
License-Update:Add BSD-3-Clause License

changlog:
================================================================

Core:
This release contains refinements, improvements, and bug fixes,
with highlights listed below.
Remove redundant work serializer usage in c-ares windows code. (#28016)
Support RDS updates on the server. (#27851)
Use WorkSerializer in XdsClient to propagate updates in a synchronized
manner. (#27975)
Support Custom Post-handshake Verification in TlsCredentials. (#25631)
Reintroduce the EventEngine default factory. (#27920)
Assert Android API >= v21. (#27943)
Add support for abstract unix domain sockets. (#27906)

Python:
[Aio] Validate the input type for set_trailing_metadata and abort. (#27958)

Signed-off-by: Xu Huan <xuhuan.fnst@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Trevor Gamblin <trevor.gamblin@windriver.com>
2021-12-21 18:47:47 -08:00

49 lines
1.4 KiB
BlitzBasic

DESCRIPTION = "Google gRPC"
HOMEPAGE = "http://www.grpc.io/"
SECTION = "devel/python"
LICENSE = "Apache-2.0 & BSD-3-Clause"
LIC_FILES_CHKSUM = "file://LICENSE;md5=6e4cf218112648d22420a84281b68b88"
DEPENDS += "${PYTHON_PN}-protobuf"
SRC_URI += "file://0001-setup.py-Do-not-mix-C-and-C-compiler-options.patch"
SRC_URI:append:class-target = " file://ppc-boringssl-support.patch \
file://boring_ssl.patch \
file://mips_bigendian.patch \
file://0001-absl-always-use-asm-sgidefs.h.patch \
"
SRC_URI[sha256sum] = "735d9a437c262ab039d02defddcb9f8f545d7009ae61c0114e19dda3843febe5"
RDEPENDS:${PN} = "${PYTHON_PN}-protobuf \
${PYTHON_PN}-setuptools \
${PYTHON_PN}-six \
"
inherit setuptools3
inherit pypi
export GRPC_PYTHON_DISABLE_LIBC_COMPATIBILITY = "1"
BORING_SSL_PLATFORM:arm = "linux-arm"
BORING_SSL_PLATFORM:x86-64 = "linux-x86_64"
BORING_SSL_PLATFORM ?= "unsupported"
export GRPC_BORING_SSL_PLATFORM = "${BORING_SSL_PLATFORM}"
BORING_SSL:x86-64 = "1"
BORING_SSL:arm = "1"
BORING_SSL ?= "0"
export GRPC_BUILD_WITH_BORING_SSL_ASM = "${BORING_SSL}"
GRPC_CFLAGS ?= ""
GRPC_CFLAGS:append:toolchain-clang = " -fvisibility=hidden -fno-wrapv -fno-exceptions"
export GRPC_PYTHON_CFLAGS = "${GRPC_CFLAGS}"
CLEANBROKEN = "1"
BBCLASSEXTEND = "native nativesdk"
CCACHE_DISABLE = "1"
# needs vdso support
COMPATIBLE_HOST:libc-musl:powerpc64le = "null"