mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-12-15 23:05:34 +01:00
d383468b25
Changelog: =========== - Use foldspaces to remove extraneous spaces. - Also minimize fullscreen windows when clicking on a task button. Document the minimization feature of task buttons and the Ctrl modifier. - Fix for keeping a menu inside the screen area. - Fixes for adjusting the workarea when moving/sizing a do-not-cover window - Fix to resize maximized windows when workarea grows and fix to recompute the workarea when a dock exits - Don't synchronize with icewm after _NET_WORKAREA changes as it slows icewm down. - Fix typo - When the workarea changes, adjust the positions of all desktop icons. - Drop excessive use of square brackets around double quotes. - Improve the abstractions for the doNotCover computation inside updateWorkAreaInner. - Add new "switchmenu" and "print" actions to icesh to use icesh in a "switchkey" definition in the "keys" file. - Make the -Z filter work on non-Linux. - Add mlterm for OpenBSD. - Explain Dock layer. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
48 lines
1.7 KiB
BlitzBasic
48 lines
1.7 KiB
BlitzBasic
DESCRIPTION = "Ice Window Manager (IceWM)"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=4a26952467ef79a7efca4a9cf52d417b"
|
|
|
|
SRC_URI = "https://github.com/ice-wm/${BPN}/releases/download/${PV}/${BPN}-${PV}.tar.lz \
|
|
file://0001-configure.ac-skip-running-test-program-when-cross-co.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "c64b1b7c8ee262a3c4796be57349a3198998564d70ed26f11e724e1b73d48394"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/ice-wm/${BPN}/releases"
|
|
UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)"
|
|
|
|
inherit autotools pkgconfig gettext perlnative features_check qemu update-alternatives
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
EXTRA_OECONF += "--with-libdir=${datadir}/icewm \
|
|
--with-cfgdir=${sysconfdir}/icewm \
|
|
--with-docdir=${docdir}/icewm \
|
|
--enable-fribidi \
|
|
--enable-xinerama \
|
|
--enable-shape"
|
|
|
|
DEPENDS = "asciidoc-native fontconfig fribidi gdk-pixbuf imlib2 libxft libxpm libxrandr \
|
|
libxinerama libice libsm libx11 libxext libxrender libxcomposite libxdamage \
|
|
libxfixes"
|
|
DEPENDS:append = " qemu-native"
|
|
RDEPENDS:${PN} = "perl fribidi imlib2 imlib2-loaders"
|
|
|
|
do_compile:prepend:class-target() {
|
|
|
|
cd ${B}
|
|
oe_runmake -C src genpref
|
|
|
|
qemu_binary="${@qemu_wrapper_cmdline(d, '${STAGING_DIR_TARGET}',['${B}/src/.libs','${STAGING_DIR_TARGET}/${libdir}','${STAGING_DIR_TARGET}/${base_libdir}'])}"
|
|
cat >qemuwrapper <<EOF
|
|
#!/bin/sh
|
|
${qemu_binary} src/genpref "\$@"
|
|
EOF
|
|
chmod +x qemuwrapper
|
|
./qemuwrapper > src/preferences
|
|
}
|
|
|
|
ALTERNATIVE:${PN} = "x-session-manager"
|
|
ALTERNATIVE_TARGET[x-session-manager] = "${bindir}/icewm-session"
|
|
ALTERNATIVE_PRIORITY_${PN} = "100"
|
|
|
|
FILES:${PN} += "${datadir}/xsessions"
|