mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2025-07-19 15:29:08 +02:00
677199bb7a
Signed-off-by: Mark Hatle <mark.hatle@windriver.com> Signed-off-by: Joe MacDonald <joe_macdonald@mentor.com>
133 lines
4.7 KiB
BlitzBasic
133 lines
4.7 KiB
BlitzBasic
SUMMARY = "NetworkManager"
|
|
SECTION = "net/misc"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=cbbffd568227ada506640fe950a4823b \
|
|
file://libnm-util/COPYING;md5=1c4fa765d6eb3cd2fbd84344a1b816cd \
|
|
file://docs/api/html/license.html;md5=8eb8e72bab097b9d11763002cb003697 \
|
|
"
|
|
|
|
DEPENDS = " \
|
|
intltool-native \
|
|
libnl \
|
|
dbus \
|
|
dbus-glib \
|
|
dbus-glib-native \
|
|
libgudev \
|
|
util-linux \
|
|
libndp \
|
|
libnewt \
|
|
polkit \
|
|
jansson \
|
|
"
|
|
|
|
inherit gnomebase gettext systemd bluetooth bash-completion vala gobject-introspection
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.xz \
|
|
file://0001-don-t-try-to-run-sbin-dhclient-to-get-the-version-nu.patch \
|
|
file://0002-Fix-nm-version-macro-includes.patch \
|
|
file://0001-adjust-net-headers-for-musl-compatibility.patch \
|
|
file://0002-socket-util.h-Include-linux-sockios.h-on-musl.patch \
|
|
file://0003-Define-ETH_ALEN.patch \
|
|
file://0004-Define-missing-features-to-cater-for-musl.patch \
|
|
file://0005-sd-lldp.h-Remove-net-ethernet.h-seems-to-be-over-spe.patch \
|
|
file://0001-check-for-strndupa-before-using-it.patch \
|
|
file://0001-dns-resolved-add-systemd-resolved-backend.patch \
|
|
file://0001-dns-resolved-also-check-for-etc-resolv-conf.systemd.patch \
|
|
file://0001-systemd-xlocale.h-is-dropped-by-newer-glibc.patch \
|
|
file://0002-user-format-string-in-g_dbus_message_new_method_erro.patch \
|
|
"
|
|
SRC_URI[md5sum] = "63f1e0d6d7e9099499d062c84c927a75"
|
|
SRC_URI[sha256sum] = "829378f318cc008d138a23ca6a9191928ce75344e7e47a2f2c35f4ac82133309"
|
|
|
|
S = "${WORKDIR}/NetworkManager-${PV}"
|
|
|
|
EXTRA_OECONF = " \
|
|
--disable-ifcfg-rh \
|
|
--disable-ifnet \
|
|
--disable-ifcfg-suse \
|
|
--disable-more-warnings \
|
|
--with-iptables=${sbindir}/iptables \
|
|
--with-tests \
|
|
--with-nmtui=yes \
|
|
"
|
|
|
|
do_compile_prepend() {
|
|
export GIR_EXTRA_LIBS_PATH="${B}/libnm-util/.libs"
|
|
}
|
|
|
|
PACKAGECONFIG ??= "nss ifupdown netconfig dhclient dnsmasq \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', 'consolekit', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', '${BLUEZ}', '', d)} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'wifi', d)} \
|
|
"
|
|
PACKAGECONFIG[systemd] = " \
|
|
--with-systemdsystemunitdir=${systemd_unitdir}/system --with-session-tracking=systemd --enable-polkit, \
|
|
--without-systemdsystemunitdir, \
|
|
polkit \
|
|
"
|
|
PACKAGECONFIG[bluez5] = "--enable-bluez5-dun,--disable-bluez5-dun,bluez5"
|
|
# consolekit is not picked by shlibs, so add it to RDEPENDS too
|
|
PACKAGECONFIG[consolekit] = "--with-session-tracking=consolekit,,consolekit,consolekit"
|
|
PACKAGECONFIG[concheck] = "--with-libsoup=yes,--with-libsoup=no,libsoup-2.4"
|
|
PACKAGECONFIG[modemmanager] = "--with-modem-manager-1=yes,--with-modem-manager-1=no,modemmanager"
|
|
PACKAGECONFIG[ppp] = "--enable-ppp,--disable-ppp,ppp,ppp"
|
|
# Use full featured dhcp client instead of internal one
|
|
PACKAGECONFIG[dhclient] = "--with-dhclient=${base_sbindir}/dhclient,,,dhcp-client"
|
|
PACKAGECONFIG[dnsmasq] = "--with-dnsmasq=${bindir}/dnsmasq"
|
|
PACKAGECONFIG[nss] = "--with-crypto=nss,,nss"
|
|
PACKAGECONFIG[gnutls] = "--with-crypto=gnutls,,gnutls"
|
|
PACKAGECONFIG[wifi] = "--enable-wifi=yes,--enable-wifi=no,wireless-tools,wpa-supplicant wireless-tools"
|
|
PACKAGECONFIG[ifupdown] = "--enable-ifupdown,--disable-ifupdown"
|
|
PACKAGECONFIG[netconfig] = "--with-netconfig=yes,--with-netconfig=no"
|
|
PACKAGECONFIG[qt4-x11-free] = "--enable-qt,--disable-qt,qt4-x11-free"
|
|
|
|
PACKAGES =+ "libnmutil libnmglib libnmglib-vpn \
|
|
${PN}-nmtui ${PN}-nmtui-doc \
|
|
${PN}-adsl \
|
|
"
|
|
|
|
FILES_libnmutil += "${libdir}/libnm-util.so.*"
|
|
FILES_libnmglib += "${libdir}/libnm-glib.so.*"
|
|
FILES_libnmglib-vpn += "${libdir}/libnm-glib-vpn.so.*"
|
|
|
|
FILES_${PN}-adsl = "${libdir}/NetworkManager/libnm-device-plugin-adsl.so"
|
|
|
|
FILES_${PN} += " \
|
|
${libexecdir} \
|
|
${libdir}/pppd/*/nm-pppd-plugin.so \
|
|
${libdir}/NetworkManager/*.so \
|
|
${datadir}/polkit-1 \
|
|
${datadir}/dbus-1 \
|
|
${base_libdir}/udev/* \
|
|
${systemd_unitdir}/system \
|
|
"
|
|
|
|
RRECOMMENDS_${PN} += "iptables \
|
|
${@bb.utils.filter('PACKAGECONFIG', 'dnsmasq', d)} \
|
|
"
|
|
RCONFLICTS_${PN} = "connman"
|
|
|
|
FILES_${PN}-dev += " \
|
|
${datadir}/NetworkManager/gdb-cmd \
|
|
${libdir}/pppd/*/*.la \
|
|
${libdir}/NetworkManager/*.la \
|
|
"
|
|
|
|
FILES_${PN}-nmtui = " \
|
|
${bindir}/nmtui \
|
|
${bindir}/nmtui-edit \
|
|
${bindir}/nmtui-connect \
|
|
${bindir}/nmtui-hostname \
|
|
"
|
|
|
|
FILES_${PN}-nmtui-doc = " \
|
|
${mandir}/man1/nmtui* \
|
|
"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "NetworkManager.service NetworkManager-dispatcher.service"
|
|
|
|
do_install_append() {
|
|
rm -rf ${D}/run ${D}${localstatedir}/run
|
|
}
|