mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-01-08 10:15:23 +01:00
e54284c063
The riscv tuples do not exist in older gnu-config Signed-off-by: Khem Raj <raj.khem@gmail.com>
71 lines
2.4 KiB
BlitzBasic
71 lines
2.4 KiB
BlitzBasic
SUMMARY = "XFS Filesystem Utilities"
|
|
HOMEPAGE = "http://oss.sgi.com/projects/xfs"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2 & LGPLv2.1"
|
|
LICENSE_libhandle = "LGPLv2.1"
|
|
LIC_FILES_CHKSUM = "file://LICENSES/GPL-2.0;md5=74274e8a218423e49eefdea80bc55038 \
|
|
file://LICENSES/LGPL-2.1;md5=b370887980db5dd40659b50909238dbd"
|
|
DEPENDS = "util-linux util-linux-native"
|
|
SRC_URI = "https://www.kernel.org/pub/linux/utils/fs/xfs/xfsprogs/${BP}.tar.xz \
|
|
file://remove_flags_from_build_flags.patch \
|
|
file://0001-build-Check-for-sync_file_range-libc-function.patch \
|
|
file://disable-xfs_scrub-build.patch \
|
|
file://0001-Check-for-MAP_SYNC-in-sys-mman.h.patch \
|
|
file://0002-include-include-xfs-linux.h-after-sys-mman.h.patch \
|
|
"
|
|
SRC_URI[md5sum] = "5f80b631b68df89a8b9283307e96d2e8"
|
|
SRC_URI[sha256sum] = "397dc96f51aeeff73d021d3418d3172377b2685f2740ca60525096c070aa3df1"
|
|
|
|
inherit autotools-brokensep
|
|
|
|
PACKAGES =+ "${PN}-fsck ${PN}-mkfs ${PN}-repair libhandle"
|
|
|
|
DEPENDS += "util-linux"
|
|
|
|
RDEPENDS_${PN} = "${PN}-fsck ${PN}-mkfs ${PN}-repair"
|
|
|
|
FILES_${PN}-fsck = "${base_sbindir}/fsck.xfs"
|
|
FILES_${PN}-mkfs = "${base_sbindir}/mkfs.xfs"
|
|
FILES_${PN}-repair = "${base_sbindir}/xfs_repair"
|
|
|
|
FILES_libhandle = "${base_libdir}/libhandle${SOLIBS}"
|
|
|
|
EXTRA_OECONF = "--enable-gettext=no \
|
|
INSTALL_USER=root \
|
|
INSTALL_GROUP=root \
|
|
ac_cv_header_aio_h=yes \
|
|
ac_cv_lib_rt_lio_listio=yes \
|
|
"
|
|
|
|
DISABLE_STATIC = ""
|
|
EXTRA_AUTORECONF += "-I ${S}/m4 --exclude=autoheader"
|
|
|
|
PACKAGECONFIG ??= "readline blkid"
|
|
|
|
PACKAGECONFIG[readline] = "--enable-readline=yes,--enable-readline=no,readline"
|
|
PACKAGECONFIG[blkid] = "--enable-blkid=yes,--enable-blkid=no,util-linux"
|
|
|
|
export DEBUG="-DNDEBUG"
|
|
export BUILD_VERBOSE="1"
|
|
export tagname="CC"
|
|
|
|
EXTRA_OEMAKE = "DIST_ROOT='${D}'"
|
|
|
|
do_configure () {
|
|
export BUILD_CC="${BUILD_CC} ${BUILD_CFLAGS}"
|
|
# Prevent Makefile from calling configure without arguments,
|
|
# when do_configure gets called for a second time.
|
|
rm -f ${B}/include/builddefs ${B}/include/platform_defs.h ${B}/configure
|
|
# Recreate configure script.
|
|
oe_runmake configure
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
|
|
oe_runconf
|
|
}
|
|
|
|
do_install_append() {
|
|
oe_runmake 'DESTDIR=${D}' install-dev
|
|
rm ${D}${libdir}/*.la
|
|
rmdir --ignore-fail-on-non-empty ${D}${libdir}
|
|
}
|