mirror of
git://git.yoctoproject.org/meta-raspberrypi.git
synced 2025-07-19 12:59:03 +02:00
bb8d5f7e9b
The firmware repo is huge ( 36G ) to clone is onerous using shallow clone tarballs require them to be pre-populated at some mirror which we don't have. Third option is to let github provide the tarball, there is concern that tarballs might change the compression etc and thus checksum would change that is something github would communicate to users in advance [1] Therefore this is the best solution for us right now. Also upgrade to latest while here and drop PR settings [1] https://docs.github.com/en/repositories/working-with-files/using-files/downloading-source-code-archives#stability-of-source-code-archives Signed-off-by: Khem Raj <raj.khem@gmail.com>
53 lines
1.5 KiB
BlitzBasic
53 lines
1.5 KiB
BlitzBasic
DESCRIPTION = "Closed source binary files to help boot all raspberry pi devices."
|
|
LICENSE = "Broadcom-RPi"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENCE.broadcom;md5=c403841ff2837657b2ed8e5bb474ac8d"
|
|
|
|
inherit deploy nopackages
|
|
|
|
RPIFW_DATE ?= "20240319"
|
|
SRCREV = "9f24f4bc2bdd07ffd158cfbb4bce88a2efc4c1f5"
|
|
SHORTREV = "${@d.getVar("SRCREV", False).__str__()[:7]}"
|
|
RPIFW_SRC_URI ?= "https://api.github.com/repos/raspberrypi/firmware/tarball/9f24f4bc2bdd07ffd158cfbb4bce88a2efc4c1f5;downloadfilename=raspberrypi-firmware-${SHORTREV}.tar.gz"
|
|
RPIFW_S ?= "${WORKDIR}/raspberrypi-firmware-${SHORTREV}"
|
|
|
|
SRC_URI = "${RPIFW_SRC_URI}"
|
|
SRC_URI[sha256sum] = "4b436f8946b139c6a1202375ef55d4848e3bcd8c1a9cb47000e06d7ecec828f7"
|
|
|
|
PV = "${RPIFW_DATE}"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
DEPENDS = "rpi-config rpi-cmdline"
|
|
|
|
COMPATIBLE_MACHINE = "^rpi$"
|
|
|
|
S = "${RPIFW_S}/boot"
|
|
|
|
PR = "r3"
|
|
|
|
do_deploy() {
|
|
install -d ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
|
|
|
|
for i in ${S}/*.elf ; do
|
|
cp $i ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
|
|
done
|
|
for i in ${S}/*.dat ; do
|
|
cp $i ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
|
|
done
|
|
for i in ${S}/*.bin ; do
|
|
cp $i ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}
|
|
done
|
|
|
|
# Add stamp in deploy directory
|
|
touch ${DEPLOYDIR}/${BOOTFILES_DIR_NAME}/${PN}-${PV}.stamp
|
|
}
|
|
|
|
do_deploy[depends] += "rpi-config:do_deploy rpi-cmdline:do_deploy"
|
|
|
|
addtask deploy before do_build after do_install
|
|
do_deploy[dirs] += "${DEPLOYDIR}/${BOOTFILES_DIR_NAME}"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|