mirror of
git://git.yoctoproject.org/meta-raspberrypi.git
synced 2025-07-19 12:59:03 +02:00
5f9423e4f9
CMake is removed in upstream libcamera-apps as of 9e17265, thus switch to meson to build the package from now on. Add PACKAGECONFIG entries and neon flags matching the settings project meson.build as described in the official documentation https://www.raspberrypi.com/documentation/computers/camera_software.html#building-libcamera-apps Default to "drm" for PACKAGECONFIG as it is the only option enabled in both recommended meson setup for Raspberry Pi OS and Raspberry Pi OS Lite. Signed-off-by: Vivien Didelot <vivien.didelot@gmail.com>
41 lines
1.5 KiB
BlitzBasic
41 lines
1.5 KiB
BlitzBasic
SUMMARY = "A suite of libcamera-based apps"
|
|
DESCRIPTION = "This is a small suite of libcamera-based apps that aim to \
|
|
copy the functionality of the existing \"raspicam\" apps."
|
|
HOMEPAGE = "https://github.com/raspberrypi/libcamera-apps"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://license.txt;md5=a0013d1b383d72ba4bdc5b750e7d1d77"
|
|
|
|
SRC_URI = "\
|
|
git://github.com/raspberrypi/libcamera-apps.git;protocol=https;branch=main \
|
|
file://0001-utils-version.py-use-usr-bin-env-in-shebang.patch \
|
|
"
|
|
PV = "1.2.1+git${SRCPV}"
|
|
SRCREV = "3d9ac1087b3d6aa9cf3758c088414d7cf518c395"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS = "libcamera libexif jpeg tiff libpng boost"
|
|
|
|
PACKAGECONFIG ??= "drm"
|
|
PACKAGECONFIG[libav] = "-Denable_libav=true, -Denable_libav=false, libav"
|
|
PACKAGECONFIG[drm] = "-Denable_drm=true, -Denable_drm=false, libdrm"
|
|
PACKAGECONFIG[egl] = "-Denable_egl=true, -Denable_egl=false, virtual/egl"
|
|
PACKAGECONFIG[qt] = "-Denable_qt=true, -Denable_qt=false, qtbase"
|
|
PACKAGECONFIG[opencv] = "-Denable_opencv=true, -Denable_opencv=false, opencv"
|
|
PACKAGECONFIG[tflite] = "-Denable_tflite=true, -Denable_tflite=false, tensorflow-lite"
|
|
|
|
inherit meson pkgconfig
|
|
|
|
NEON_FLAGS = ""
|
|
NEON_FLAGS:aarch64 = "-Dneon_flags=arm64"
|
|
NEON_FLAGS:arm:raspberrypi3 = "-Dneon_flags=armv8-neon"
|
|
NEON_FLAGS:arm:raspberrypi4 = "-Dneon_flags=armv8-neon"
|
|
EXTRA_OEMESON += "${NEON_FLAGS}"
|
|
|
|
# QA Issue: /usr/bin/camera-bug-report contained in package libcamera-apps requires /usr/bin/python3
|
|
do_install:append() {
|
|
rm -v ${D}/${bindir}/camera-bug-report
|
|
}
|