mirror of
git://git.yoctoproject.org/meta-raspberrypi.git
synced 2025-10-22 14:52:18 +02:00
b32d1172a3
Package rpicam_app.so.1.4.2 library for the default package to fix the
following error.
ERROR: libcamera-apps-1.4.2+git-r0 do_package: QA Issue: libcamera-apps: Files/directories were installed but not shipped in any package:
/usr/lib/rpicam_app.so.1.4.2
Please set FILES such that these items are packaged. Alternatively if they are unneeded, avoid installing them or delete them within do_install.
libcamera-apps: 1 installed and not shipped files. [installed-vs-shipped]
ERROR: libcamera-apps-1.4.2+git-r0 do_package: Fatal QA errors were found, failing task.
ERROR: Logfile of failure stored in: /home/build-2/tmp/work/cortexa53-poky-linux/libcamera-apps/1.4.2+git/temp/log.do_package.1110484
ERROR: Task (/home/meta-raspberrypi/dynamic-layers/multimedia-layer/recipes-multimedia/libcamera-apps/libcamera-apps_git.bb:do_package) failed with exit code '1'
The following version expansion is used to make it compatible with future
package version changes.
${@d.getVar("PV", False).__str__().split('+')[0]}"
Fixes: https://github.com/agherzan/meta-raspberrypi/issues/1440
Signed-off-by: Bhargav Das <bhargavdas100@gmail.com>
45 lines
1.8 KiB
BlitzBasic
45 lines
1.8 KiB
BlitzBasic
SUMMARY = "A suite of libcamera-based apps"
|
|
DESCRIPTION = "This is a small suite of libcamera-based apps that aim to \
|
|
copy the functionality of the existing \"raspicam\" apps."
|
|
HOMEPAGE = "https://github.com/raspberrypi/libcamera-apps"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://license.txt;md5=a0013d1b383d72ba4bdc5b750e7d1d77"
|
|
|
|
SRC_URI = "\
|
|
git://github.com/raspberrypi/libcamera-apps.git;protocol=https;branch=main \
|
|
file://0001-utils-version.py-use-usr-bin-env-in-shebang.patch \
|
|
file://0002-Revert-Support-compressed-pixel-formats-when-saving-.patch \
|
|
"
|
|
PV = "1.4.2+git${SRCPV}"
|
|
SRCREV = "9ae39f85ae6bee9761c36b9b5b80d675bc1fa369"
|
|
|
|
DEPENDS = "libcamera libexif jpeg tiff libpng boost"
|
|
|
|
PACKAGECONFIG ??= "drm"
|
|
PACKAGECONFIG[libav] = "-Denable_libav=true, -Denable_libav=false, libav"
|
|
PACKAGECONFIG[drm] = "-Denable_drm=true, -Denable_drm=false, libdrm"
|
|
PACKAGECONFIG[egl] = "-Denable_egl=true, -Denable_egl=false, virtual/egl"
|
|
PACKAGECONFIG[qt] = "-Denable_qt=true, -Denable_qt=false, qtbase"
|
|
PACKAGECONFIG[opencv] = "-Denable_opencv=true, -Denable_opencv=false, opencv"
|
|
PACKAGECONFIG[tflite] = "-Denable_tflite=true, -Denable_tflite=false, tensorflow-lite"
|
|
|
|
inherit meson pkgconfig
|
|
|
|
NEON_FLAGS = ""
|
|
NEON_FLAGS:aarch64 = "-Dneon_flags=arm64"
|
|
NEON_FLAGS:arm:raspberrypi3 = "-Dneon_flags=armv8-neon"
|
|
NEON_FLAGS:arm:raspberrypi4 = "-Dneon_flags=armv8-neon"
|
|
EXTRA_OEMESON += "${NEON_FLAGS}"
|
|
|
|
# QA Issue: /usr/bin/camera-bug-report contained in package libcamera-apps requires /usr/bin/python3
|
|
do_install:append() {
|
|
rm -v ${D}/${bindir}/camera-bug-report
|
|
}
|
|
|
|
# not picked automatically, because it's missing common 'lib' prefix
|
|
FILES:${PN}-dev += "${libdir}/rpicam_app.so"
|
|
|
|
FILES:${PN} += "${libdir}/rpicam_app.so.${@d.getVar("PV", False).__str__().split('+')[0]}"
|