virt-viewer: add recipe

virt-viewer is a minimal tool for displaying the graphical console of a virtual machine.
The console is accessed using the VNC or SPICE protocol. The guest can be referred to
based on its name, ID, or UUID. If the guest is not already running, then the viewer can
be told to wait until it starts before attempting to connect to the console. The viewer
can connect directly to both local and remotely hosted machines , optionally using SSL/TLS
encryption.

virt-viewer is the required client for the debian based proxmox ve. That's also the environ-
ment for which it was tested at runtime (only on x86_64).

I have successfully compiled it for x86_64, aarch64 and qemumips. Other platforms might work
(as long as gobject-introspection is available), but are untested.
Adding the vnc protocol would pull in a layer dependency on meta-gnome.

Signed-off-by: Markus Volk <f_l_k@t-online.de>
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>

recipes-extended/virt-viewer/virt-viewer_11.0.bb

@@ -0,0 +1,29 @@
+SUMMARY = "Virtual Machine Viewer"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
+
+# for ovirt support librest-0.7 and libgovirt would be needed
+DEPENDS = " \
+	desktop-file-utils-native \
+	glib-2.0 \
+	gtk+3 \
+	libxml2 \
+"
+
+SRC_URI = "git://gitlab.com/virt-viewer/virt-viewer.git;protocol=https;branch=master"
+
+SRCREV = "1e99e5e4f409da91638eb79067ec738994c28ef5"
+PV = "11.0+git${SRCPV}"
+S = "${WORKDIR}/git"
+
+PACKAGECONFIG ?= "libvirt spice vte"
+
+PACKAGECONFIG[libvirt] = "-Dlibvirt=enabled,-Dlibvirt=disabled,libvirt libvirt-glib"
+PACKAGECONFIG[spice] = "-Dspice=enabled,-Dspice=disabled,spice-gtk spice-protocol"
+PACKAGECONFIG[vnc] = "-Dvnc=enabled,-Dvnc=disabled,gtk-vnc"
+PACKAGECONFIG[vte] = "-Dvte=enabled,-Dvte=disabled,vte"
+
+inherit meson pkgconfig gtk-icon-cache mime mime-xdg gobject-introspection
+
+FILES:${PN} += "${datadir}"
+GIR_MESON_OPTION = ''