MIRRORS/meta-virtualization
1
0
Fork 0
mirror of git://git.yoctoproject.org/meta-virtualization.git synced 2025-07-19 12:50:22 +02:00
Code Issues Actions Packages Projects Releases Wiki Activity

lopper: update to v1.0 and setuptools based project

Browse Source 
Switching to lopper 1.0 brings us a more standard setuptools
based project for install and packaging.

This update also fixes the experimental update to master-next,
which was incomplete and broken.

The only signficant user visible change with this update is
that lopper.py is now 'lopper' and any calling recipes need
to be updated accordingly.

Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
This commit is contained in:
Bruce Ashfield 2021-11-08 21:57:02 -05:00
parent 7223f80a2b
commit f3e3653d4d
2 changed files with 31 additions and 45 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

45
recipes-kernel/lopper/lopper.bb
View File

@ -1,45 +0,0 @@
SUMMARY = "Device Tree Lopper"
DESCRIPTION = "Tool for manipulation of system device tree files"
LICENSE = "BSD-3-Clause"
SECTION = "bootloader"
SRC_URI = "git://github.com/devicetree-org/lopper.git;branch=master-next;protocol=https"
SRCREV = "3e6aa522d2469ba7563fc6691802cf4aae3d2fd7"
S = "${WORKDIR}/git"
LIC_FILES_CHKSUM = "file://LICENSE.md;md5=8e5f5f691f01c9fdfa7a7f2d535be619"
RDEPENDS:${PN} = " \
python3-core \
python3-dtc \
python3-humanfriendly \
"
do_install() {
install -d "${D}/${bindir}"
install -d "${D}/${datadir}/${BPN}"
install -m 0644 "${S}/README.md" "${D}/${datadir}/${BPN}"
install -m 0644 "${S}/README-architecture.md" "${D}/${datadir}/${BPN}"
install -m 0644 "${S}/README.pydoc" "${D}/${datadir}/${BPN}"
install -m 0644 "${S}/LICENSE.md" "${D}/${datadir}/${BPN}"
install -d "${D}/${datadir}/${BPN}/lopper/assists"
cp -r "${S}/lopper/assists/"* "${D}/${datadir}/${BPN}/lopper/assists/"
install -d "${D}/${datadir}/${BPN}/lopper/lops"
install -m 0644 "${S}/lopper/lops/"* "${D}/${datadir}/${BPN}/lopper/lops/"
install -d "${D}/${datadir}/${BPN}/device-trees"
install -m 0644 "${S}/device-trees/"* "${D}/${datadir}/${BPN}/device-trees/"
install -m 0755 "${S}/"lopper*.py "${D}/${datadir}/${BPN}/"
datadir_relpath=${@os.path.relpath(d.getVar('datadir'), d.getVar('bindir'))}
ln -s "${datadir_relpath}/${BPN}/lopper.py" "${D}/${bindir}/"
}
do_configure[noexec] = "1"
do_compile[noexec] = "1"
BBCLASSEXTEND = "native nativesdk"

31
recipes-kernel/lopper/lopper_git.bb Normal file
View File

@ -0,0 +1,31 @@
SUMMARY = "Device Tree Lopper"
DESCRIPTION = "Tool for manipulation of system device tree files"
LICENSE = "BSD-3-Clause"
SECTION = "bootloader"
SRC_URI = "git://github.com/devicetree-org/lopper.git;branch=master;protocol=https"
SRCREV = "3c81fcce08eeb64cbbde1535abd83572985a8689"
S = "${WORKDIR}/git"
PV="v1.0+git${SRCPV}"
LIC_FILES_CHKSUM = "file://LICENSE.md;md5=8e5f5f691f01c9fdfa7a7f2d535be619"
RDEPENDS:${PN} = " \
python3-core \
python3-dtc \
python3-humanfriendly \
"
inherit setuptools3
INHIBIT_PACKAGE_STRIP = "1"
do_install:append() {
# we have to remove the vendor'd libfdt, since an attempt to strip it
# will be made, and it will fail in a cross environment.
rm -rf ${D}/${PYTHON_SITEPACKAGES_DIR}/${BPN}/vendor
}
BBCLASSEXTEND = "native nativesdk"