mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
01a8d45370
Recently in the oe-core the go.bbclass changed and requires the defition of the GO_IMPORT variable. This was intended to simplify how the compilation works with go packages and it is still a work in progress. This patch set makes the recipes compatible to generate the same end result as before using the new go.bbclass from oe-core. Any patches that were included in the recipes had to have the paths adjusted because the new go.bbclass manipulates the notion of S to be S + "src" + "$GO_IMPORT" internally for the purpose of unpack, patch and compile. Signed-off-by: Jason Wessel <jason.wessel@windriver.com> Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com>
47 lines
1.5 KiB
BlitzBasic
47 lines
1.5 KiB
BlitzBasic
HOMEPAGE = "https://github.com/jfrazelle/netns"
|
|
SUMMARY = "Runc hook for setting up default bridge networking."
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://src/import/LICENSE;md5=20ce4c6a4f32d6ee4a68e3a7506db3f1"
|
|
|
|
SRC_URI = "git://github.com/jessfraz/netns;branch=master"
|
|
SRCREV = "85b1ab9fcccbaa404a2636b52a48bbde02437cf7"
|
|
PV = "0.1.0+git${SRCPV}"
|
|
GO_IMPORT = "import"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit goarch
|
|
inherit go
|
|
|
|
do_compile() {
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
export GOROOT="${STAGING_LIBDIR_NATIVE}/${TARGET_SYS}/go"
|
|
# Setup vendor directory so that it can be used in GOPATH.
|
|
#
|
|
# Go looks in a src directory under any directory in GOPATH but netns
|
|
# uses 'vendor' instead of 'vendor/src'. We can fix this with a symlink.
|
|
#
|
|
# We also need to link in the ipallocator directory as that is not under
|
|
# a src directory.
|
|
ln -sfn . "${S}/src/import/vendor/src"
|
|
mkdir -p "${S}/src/import/vendor/src/github.com/jessfraz/netns"
|
|
ln -sfn "${S}/src/import/ipallocator" "${S}/src/import/vendor/src/github.com/jessfraz/netns/ipallocator"
|
|
export GOPATH="${S}/src/import/vendor"
|
|
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CFLAGS=""
|
|
export LDFLAGS=""
|
|
export CGO_CFLAGS="${BUILDSDK_CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CGO_LDFLAGS="${BUILDSDK_LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
|
|
cd ${S}/src/import
|
|
oe_runmake static
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/${sbindir}
|
|
install ${S}/src/import/netns ${D}/${sbindir}/netns
|
|
}
|