mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 20:59:41 +02:00
02ee2b38d4
recipes that use multiple SCMs in the SRC_URI, must supply SRCREV_FORMAT or SRCPV triggers an expansion error. While this isn't fatal during the build, it can cause issues with setscene (and possibly) other tasks failing, which then leads to no sstate re-use, etc. Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
120 lines
4.6 KiB
BlitzBasic
120 lines
4.6 KiB
BlitzBasic
HOMEPAGE = "git://github.com/kubernetes/kubernetes"
|
|
SUMMARY = "Production-Grade Container Scheduling and Management"
|
|
DESCRIPTION = "Kubernetes is an open source system for managing containerized \
|
|
applications across multiple hosts, providing basic mechanisms for deployment, \
|
|
maintenance, and scaling of applications. \
|
|
"
|
|
|
|
PV = "v1.20.9+git${SRCREV_kubernetes}"
|
|
SRCREV_kubernetes = "7a576bc3935a6b555e33346fd73ad77c925e9e4a"
|
|
SRCREV_kubernetes-release = "cf1e18a801c2ec6cc8c3d3b83bf1cbc4cf0dbc53"
|
|
SRCREV_FORMAT ?= "kubernetes_release"
|
|
|
|
SRC_URI = "git://github.com/kubernetes/kubernetes.git;branch=release-1.20;name=kubernetes \
|
|
git://github.com/kubernetes/release;branch=master;name=kubernetes-release;destsuffix=git/release \
|
|
file://0001-hack-lib-golang.sh-use-CC-from-environment.patch \
|
|
file://0001-cross-don-t-build-tests-by-default.patch \
|
|
file://0001-generate-bindata-unset-GOBIN.patch \
|
|
file://0001-build-golang.sh-convert-remaining-go-calls-to-use.patch \
|
|
file://0001-Makefile.generated_files-Fix-race-issue-for-installi.patch \
|
|
file://CVE-2021-20206.patch \
|
|
"
|
|
|
|
DEPENDS += "rsync-native \
|
|
coreutils-native \
|
|
go-native \
|
|
"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://src/import/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
inherit systemd
|
|
inherit go
|
|
inherit goarch
|
|
|
|
COMPATIBLE_HOST = '(x86_64.*|arm.*|aarch64.*)-linux'
|
|
|
|
do_compile() {
|
|
# link fixups for compilation
|
|
rm -f ${S}/src/import/vendor/src
|
|
ln -sf ./ ${S}/src/import/vendor/src
|
|
|
|
export GOPATH="${S}/src/import/.gopath:${S}/src/import/vendor:${STAGING_DIR_TARGET}/${prefix}/local/go"
|
|
cd ${S}/src/import
|
|
|
|
# Build the host tools first, using the host compiler
|
|
export GOARCH="${BUILD_GOARCH}"
|
|
# Pass the needed cflags/ldflags so that cgo can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CFLAGS="${BUILD_CFLAGS}"
|
|
export LDFLAGS="${BUILD_LDFLAGS}"
|
|
export CGO_CFLAGS="${BUILD_CFLAGS}"
|
|
# as of go 1.15.5, there are some flags the CGO doesn't like. Rather than
|
|
# clearing them all, we sed away the ones we don't want.
|
|
export CGO_LDFLAGS="$(echo ${BUILD_LDFLAGS} | sed 's/-Wl,-O1//g' | sed 's/-Wl,--dynamic-linker.*?( \|$\)//g')"
|
|
export CC="${BUILD_CC}"
|
|
export LD="${BUILD_LD}"
|
|
|
|
make generated_files GO="go" KUBE_BUILD_PLATFORMS="${HOST_GOOS}/${BUILD_GOARCH}"
|
|
|
|
# Build the target binaries
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
# Pass the needed cflags/ldflags so that cgo can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CFLAGS=""
|
|
export LDFLAGS=""
|
|
export CC="${CC}"
|
|
export LD="${LD}"
|
|
export GOBIN=""
|
|
|
|
# to limit what is built, use 'WHAT', i.e. make WHAT=cmd/kubelet
|
|
make cross CGO_FLAGS=${CGO_FLAGS} GO=${GO} KUBE_BUILD_PLATFORMS=${GOOS}/${GOARCH} GOLDFLAGS=""
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${bindir}
|
|
install -d ${D}${systemd_unitdir}/system/
|
|
install -d ${D}${systemd_unitdir}/system/kubelet.service.d/
|
|
|
|
install -d ${D}${sysconfdir}/kubernetes/manifests/
|
|
|
|
install -m 755 -D ${S}/src/import/_output/local/bin/${TARGET_GOOS}/${TARGET_GOARCH}/* ${D}/${bindir}
|
|
|
|
install -m 0644 ${WORKDIR}/git/release/cmd/kubepkg/templates/latest/deb/kubelet/lib/systemd/system/kubelet.service ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${WORKDIR}/git/release/cmd/kubepkg/templates/latest/deb/kubeadm/10-kubeadm.conf ${D}${systemd_unitdir}/system/kubelet.service.d/
|
|
}
|
|
|
|
PACKAGES =+ "kubeadm kubectl kubelet kube-proxy ${PN}-misc"
|
|
|
|
ALLOW_EMPTY_${PN} = "1"
|
|
INSANE_SKIP_${PN} += "ldflags already-stripped"
|
|
INSANE_SKIP_${PN}-misc += "ldflags already-stripped"
|
|
|
|
# Note: we are explicitly *not* adding docker to the rdepends, since we allow
|
|
# backends like cri-o to be used.
|
|
RDEPENDS_${PN} += "kubeadm \
|
|
kubectl \
|
|
kubelet \
|
|
cni"
|
|
|
|
RDEPENDS_kubeadm = "kubelet kubectl"
|
|
FILES_kubeadm = "${bindir}/kubeadm ${systemd_unitdir}/system/kubelet.service.d/*"
|
|
|
|
RDEPENDS_kubelet = "iptables socat util-linux ethtool iproute2 ebtables iproute2-tc"
|
|
FILES_kubelet = "${bindir}/kubelet ${systemd_unitdir}/system/kubelet.service ${sysconfdir}/kubernetes/manifests/"
|
|
|
|
SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES','systemd','kubelet','',d)}"
|
|
SYSTEMD_SERVICE_kubelet = "${@bb.utils.contains('DISTRO_FEATURES','systemd','kubelet.service','',d)}"
|
|
SYSTEMD_AUTO_ENABLE_kubelet = "enable"
|
|
|
|
FILES_kubectl = "${bindir}/kubectl"
|
|
FILES_kube-proxy = "${bindir}/kube-proxy"
|
|
FILES_${PN}-misc = "${bindir}"
|
|
|
|
|
|
deltask compile_ptest_base
|