mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-12-13 21:55:23 +01:00
03eb707025
We drop a patch that is now in the upstrem project, as well as the
new commits below:
Bumping distribution to version v3.0.0-63-g76fe6170, which comprises the following commits:
0e77b285 chore: labeler: add area/client mapping for internal/client/**
2f1a51dc client: add Accept headers to Exists() HEAD
ad5d9994 build(deps): bump github/codeql-action from 4.30.7 to 4.30.8
6d764586 build(deps): bump github/codeql-action from 3.26.5 to 4.30.7
11519e6d build(deps): bump ossf/scorecard-action from 2.4.2 to 2.4.3
99c47b61 build(deps): bump actions/labeler from 5 to 6
e1e5d051 build(deps): bump actions/setup-go from 5 to 6
f5512709 build(deps): bump actions/upload-pages-artifact from 3 to 4
0fb77d6a Fix broken link to Docker Hub fair use policy
251bf1b9 build(deps): bump actions/checkout from 4 to 5
6e59b824 Fixes #4683 - uses X/Y instead of Gx/Gy for thumbprint of ecdsa keys
b559f27a Switch to UUIDv7
b39441b1 Fix markdown syntax for OTEL traces link in docs
53dde7fc fix: set OTEL traces to disabled by default
68cd681b docs: Add note about `OTEL_TRACES_EXPORTER`
1fc84617 fix tests
02b1f6e3 fix(registry/handlers/app): redis CAs
bb278c2b fix: fixed data race in TestSchedule test
b09be3d6 build(deps): bump ossf/scorecard-action from 2.4.1 to 2.4.2
6970080b s3-aws: fix build for 386
e629f886 docs: Add OpenTelemetry links to quickstart docs (#4270)
fea36383 refactor: replace map iteration with maps.Copy/Clone
369663e4 Fix S3 driver loglevel param
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
78 lines
2.6 KiB
BlitzBasic
78 lines
2.6 KiB
BlitzBasic
HOMEPAGE = "http://github.com/docker/distribution"
|
|
SUMMARY = "The Docker toolset to pack, ship, store, and deliver content"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=d2794c0df5b907fdace235a619d80314"
|
|
|
|
SRCREV_distribution = "76fe6170526f0a1046c340c20b041a090d8dbfc9"
|
|
SRC_URI = "git://github.com/docker/distribution.git;branch=main;name=distribution;destsuffix=git/src/github.com/distribution/distribution/v3;protocol=https \
|
|
file://docker-registry.service \
|
|
file://0001-build-use-to-use-cross-go-compiler.patch \
|
|
"
|
|
|
|
PACKAGES =+ "docker-registry"
|
|
|
|
PV = "v3.0.0"
|
|
S = "${UNPACKDIR}/git/src/github.com/distribution/distribution/v3"
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
inherit goarch go systemd
|
|
|
|
# This disables seccomp and apparmor, which are on by default in the
|
|
# go package.
|
|
EXTRA_OEMAKE = "BUILDTAGS=''"
|
|
|
|
do_compile() {
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
export GOPATH="${UNPACKDIR}/git/"
|
|
export GOROOT="${STAGING_LIBDIR}/go"
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CFLAGS=""
|
|
export LDFLAGS=""
|
|
export CGO_CFLAGS="${TARGET_CFLAGS}"
|
|
export GO_GCFLAGS=""
|
|
export CGO_LDFLAGS="${TARGET_LDFLAGS}"
|
|
export GO111MODULE=off
|
|
export GO_BUILD_FLAGS="-trimpath"
|
|
|
|
cd ${S}
|
|
|
|
# See https://github.com/distribution/distribution/issues/4627
|
|
sed -i -e 's#+unknown##' version/version.go
|
|
oe_runmake binaries
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/${sbindir}
|
|
install ${S}/bin/registry ${D}/${sbindir}
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 644 ${UNPACKDIR}/docker-registry.service ${D}/${systemd_unitdir}/system
|
|
fi
|
|
|
|
install -d ${D}/${sysconfdir}/docker-distribution/registry/
|
|
install ${S}/cmd/registry/config-example.yml ${D}/${sysconfdir}/docker-distribution/registry/config.yml
|
|
|
|
# storage for the registry containers
|
|
install -d ${D}/${localstatedir}/lib/registry/
|
|
}
|
|
|
|
INSANE_SKIP:${PN} += "ldflags already-stripped"
|
|
INSANE_SKIP:${MLPREFIX}docker-registry += "ldflags already-stripped textrel"
|
|
|
|
FILES:docker-registry = "${sbindir}/*"
|
|
FILES:docker-registry += "${systemd_unitdir}/system/docker-registry.service"
|
|
FILES:docker-registry += "${sysconfdir}/docker-distribution/*"
|
|
FILES:docker-registry += "${localstatedir}/lib/registry/"
|
|
|
|
SYSTEMD_PACKAGES = "docker-registry"
|
|
SYSTEMD_SERVICE:docker-registry = "${@bb.utils.contains('DISTRO_FEATURES','systemd','docker-registry.service','',d)}"
|
|
SYSTEMD_AUTO_ENABLE:docker-registry = "enable"
|
|
|
|
RDEPENDS:${PN}-ptest:remove = "${PN}"
|
|
|
|
CVE_PRODUCT = "docker_registry"
|