mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
0b47478ebc
Bumping crun to version 1.19.1-13-g6f010b5f, which comprises the following commits:
25efd10a Remove surplus ENOENT error check
99f2824f utils: return error from set_home_env() if the user was not found
3158e491 criu: improve error handling for CRIU function calls
3cd9c2c9 criu: do not set network_lock if not specified
a542ecc7 github: enable unprivileged userns
38122ac9 test: fix compiler warnings
ec5947ce TMT: Add sanity tests from c9s downstream
d08e304a Packit: Remove RHEL jobs
3e32a70c NEWS: tag 1.19.1
8b972be9 linux: fix a hang if there are no reads from the tty
e50e47ca libcrun: add ring buffer implementation
20ec0982 utils: extend epoll_helper to monitor writeable fds
77a72bdf utils: use bool for set_blocking_fd()
5f9ca9eb utils: skip copy_file_range if not usable
e2380490 tests: adjust test to upstream code
d7933486 build-aux: use an init process for the nix container
0ec1522b nix: update packages list
9b014718 Generated crun.1
d700d9db Add missing periods at the end of sentence
1832c170 linux: remove tmpmount workaround
9e3615a4 ci: build tests_libcrun_fuzzer before fuzzing
6b2e6193 build: use libtool to create libcrun_testing
3c5292b2 build: don't compile tests during normal build
db31c42a NEWS: tag 1.19
c4f8c87a checkpoint/restore: allow passing network lock method to libcriu
1942efc9 Handle case where cgroup v1 freezer is disabled
b366a785 wamr: revitalize wamr handler
21219504 cgroup, systemd: do not override devices on update
d1531073 error: 'CHAR_BIT' undeclared. fix compile failure with musl libc
5d66b309 build: Don't build cloned_binary as part of crun
fd69065d test: add new test for exec-cpu-affinity
b941d6c5 linux: move reset cpu affinity to scheduler
ef33259c linux: honor exec cpu affinity mask
047b7485 src: move cpuset_string_to_bitmask to utils
2c8088c4 libocispec: sync
42b959b5 container: initialize max caps before accessing process block
46bd62b1 cgroup: do not stop process on exec
19bbd8da utils: silence compiler warning
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
58 lines
2.3 KiB
BlitzBasic
58 lines
2.3 KiB
BlitzBasic
DESCRIPTION = "A fast and low-memory footprint OCI Container Runtime fully written in C."
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
PRIORITY = "optional"
|
|
|
|
SRCREV_crun = "6f010b5f6bd86d27e6a85eb0e933a8cca1ede71c"
|
|
SRCREV_libocispec = "5ffd4dd9fa684e0ffb2f0b5ea4a6cb638b021397"
|
|
SRCREV_ispec = "c66e8113cbad252a418d85f061bd1a20d0904d08"
|
|
SRCREV_rspec = "9505701eb390445ef7edf2be3bd3d7bc1f14eae5"
|
|
SRCREV_yajl = "f344d21280c3e4094919fd318bc5ce75da91fc06"
|
|
|
|
SRCREV_FORMAT = "crun_rspec"
|
|
SRC_URI = "git://github.com/containers/crun.git;branch=main;name=crun;protocol=https \
|
|
git://github.com/containers/libocispec.git;branch=main;name=libocispec;destsuffix=git/libocispec;protocol=https \
|
|
git://github.com/opencontainers/runtime-spec.git;branch=main;name=rspec;destsuffix=git/libocispec/runtime-spec;protocol=https \
|
|
git://github.com/opencontainers/image-spec.git;branch=main;name=ispec;destsuffix=git/libocispec/image-spec;protocol=https \
|
|
git://github.com/containers/yajl.git;branch=main;name=yajl;destsuffix=git/libocispec/yajl;protocol=https \
|
|
"
|
|
|
|
PV = "v1.19.1+git${SRCREV_crun}"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep pkgconfig
|
|
|
|
# if this is true, we'll symlink crun to runc for easier integration
|
|
# with container stacks
|
|
CRUN_AS_RUNC ?= "true"
|
|
|
|
PACKAGECONFIG ??= " \
|
|
caps external-yajl man \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'seccomp', 'seccomp', '', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[caps] = "--enable-caps,--disable-caps,libcap"
|
|
PACKAGECONFIG[external-yajl] = "--disable-embedded-yajl,--enable-embedded-yajl,yajl"
|
|
# whether to regenerate manpages that are already present in the repo
|
|
PACKAGECONFIG[man] = ",,go-md2man-native"
|
|
PACKAGECONFIG[seccomp] = "--enable-seccomp,--disable-seccomp,libseccomp"
|
|
PACKAGECONFIG[systemd] = "--enable-systemd,--disable-systemd,systemd"
|
|
|
|
DEPENDS = "m4-native"
|
|
DEPENDS:append:libc-musl = " argp-standalone"
|
|
|
|
do_configure:prepend () {
|
|
# extracted from autogen.sh in crun source. This avoids
|
|
# git submodule fetching.
|
|
mkdir -p m4
|
|
autoreconf -fi
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
if [ -n "${CRUN_AS_RUNC}" ]; then
|
|
ln -sr "${D}/${bindir}/crun" "${D}${bindir}/runc"
|
|
fi
|
|
}
|